社区 › Auto Lisp › 从中点算起的矩形

CadFrank 发表于 2022-7-5 18:07:51

从中点算起的矩形

你好
 
我想知道是否可以像SolidWorks中那样从中点创建矩形。
 
当做

Tharwat 发表于 2022-7-5 18:14:32

嗨，弗兰克，
 
这意味着你想把一个矩形分成四个矩形吗？
如果没有，请举例说明。

CadFrank 发表于 2022-7-5 18:21:36

你知道当你使用“getcorner”时，你会看到一个矩形。
 
所以我想看到矩形从中间乌鸦。
 
我已经创建了一个Lisp例程，可以生成一个矩形，但没有预览它的外观。

hanhphuc 发表于 2022-7-5 18:26:19

（如果（不是
（命令“多边形”））
;4边&割礼&半半径？
（塔瓦特会帮忙）
); if结束

rkent 发表于 2022-7-5 18:30:47

 
+1
 
反应很好！

Tharwat 发表于 2022-7-5 18:33:39

@韩，我完全忘记了多边形命令
 
很高兴看到你到处发帖。

Lee Mac 发表于 2022-7-5 18:36:20

考虑以下示例：
(defun c:crec ( / a b f l p q x z )
   (if (setq p (getpoint "\nSpecify center of rectangle: "))
       (progn
         (setq z (trans '(0 0 1) 1 0 t)
               f
               (lambda ( a v )
                   (list
                     (mapcar '+ a v)
                     (mapcar '+ a (list (- (car v)) (cadr v)))
                     (mapcar '- a v)
                     (mapcar '+ a (list (car v) (- (cadr v))))
                   )
               )
         )
         (while (= 5 (car (setq q (grread t 13 0))))
               (redraw)
               (setq l (f p (mapcar '- (cadr q) p)))
               (mapcar '(lambda ( a b ) (grdraw a b -1)) (cons (last l) l) l)
         )
         (if (= 3 (car q))
               (entmake
                   (append
                      '(
                           (000 . "LWPOLYLINE")
                           (100 . "AcDbEntity")
                           (100 . "AcDbPolyline")
                           (090 . 4)
                           (070 . 1)
                     )
                     (mapcar '(lambda ( x ) (cons 10 (trans x 1 z))) (f p (mapcar '- (cadr q) p)))
                     (list (cons 210 z))
                   )
               )
         )
       )
   )
   (redraw) (princ)
)
然而，上述方法使用grread，因此牺牲了所有标准绘图辅助工具（对象捕捉、正交模式、跟踪等）。

hanhphuc 发表于 2022-7-5 18:40:17

谢谢你也和我在一起，我很高兴这里需要你们这些目光敏锐的人
 
 
还没有。。如果是方形矩形，但不是不规则的长x宽，则命令多边形很容易
 
 
我不知道solidworks，所以我只想在这里订阅

hanhphuc 发表于 2022-7-5 18:47:43

真 的！！你的编码速度比我回复Tharwat的帖子#6快
像往常一样好主意李

Lee Mac 发表于 2022-7-5 18:53:22

 
谢谢

查看完整版本: 从中点算起的矩形