社区 › Auto Lisp › 连接终点线-crea

CafeJr 发表于 2022-7-6 02:20:12

连接终点线-crea

大家好，
 
我再一次需要帮助。。。
 
有人知道如何与下图中的线条链接？我画了一条需要闭合的线来形成一个区域，但是，要做到这一点，需要得到一些线，做一条等高线，连接点。。。
 
谢谢
 

troggarf 发表于 2022-7-6 02:27:29

检查此线程。
http://www.cadtutor.net/forum/showthread.php?48022-样条lisp
~格雷格

pBe 发表于 2022-7-6 02:31:04

 
那些圆圈是什么？它们是“绘制线”的一部分，还是只是连接轮廓的指南？一如既往，您需要提供一个绘图示例。
 
特罗加夫发布的链接看起来很有希望。

CafeJr 发表于 2022-7-6 02:35:38

 
圆圈只是显示我需要链接的点！。。。

Tharwat 发表于 2022-7-6 02:42:22

我的版本
 

(defun c:Test (/ ss in en st nd up dn u d)
;;   Tharwat 18.Oct.2013    ;;
(if (setq ss (ssget '((0 . "LINE"))))
   (progn
   (repeat (setq in (sslength ss))
       (setq en (entget (ssname ss (setq in (1- in))))
             st (cdr (assoc 10 en))
             nd (cdr (assoc 11 en))
       )
       (if (> (cadr st) (cadr nd))
         (setq up (cons st up)
               dn (cons nd dn)
         )
         (setq dn (cons st dn)
               up (cons nd up)
         )
       )
   )
   (setq u (vl-sort up '(lambda (a b) (< (car a) (car b))))
         d (vl-sort dn '(lambda (j k) (< (car j) (car k))))
   )
   (while (> (length u) 1)
       (entmakex
         (list '(0 . "LINE") (cons 10 (car u)) (cons 11 (cadr u)))
       )
       (setq u (cdr u))
   )
   (while (> (length d) 1)
       (entmakex
         (list '(0 . "LINE") (cons 10 (car d)) (cons 11 (cadr d)))
       )
       (setq d (cdr d))
   )
   )
)
(princ)
)

CafeJr 发表于 2022-7-6 02:47:55

 
谢谢你“特洛加夫”。。。我正在研究代码。。。可能就是它！。。。（但使用pline，代码上没有样条！…）

Tharwat 发表于 2022-7-6 02:54:26

这个画的是多段线。
 

(defun c:Test (/ _LW ss in en st nd up dn u d)
;;   Tharwat 18.Oct.2013    ;;
(defun _LW (lst)
   (entmakex
   (append (list '(0 . "LWPOLYLINE")
                   '(100 . "AcDbEntity")
                   '(100 . "AcDbPolyline")
                   (cons 90 (length lst))
                   '(70 . 0)
             )
             (mapcar (function (lambda (p) (cons 10 p))) lst)
   )
   )
)
(if (setq ss (ssget '((0 . "LINE"))))
   (progn
   (repeat (setq in (sslength ss))
       (setq en (entget (ssname ss (setq in (1- in))))
             st (cdr (assoc 10 en))
             nd (cdr (assoc 11 en))
       )
       (if (> (cadr st) (cadr nd))
         (setq up (cons st up)
               dn (cons nd dn)
         )
         (setq dn (cons st dn)
               up (cons nd up)
         )
       )
   )
   (setq u (vl-sort up '(lambda (a b) (< (car a) (car b))))
         d (vl-sort dn '(lambda (j k) (< (car j) (car k))))
   )
   (if (> (length u) 1)
       (_LW u)
   )
   (if (> (length d) 1)
       (_LW d)
   )
   )
)
(princ)
)

CafeJr 发表于 2022-7-6 02:56:33

Tharwat，这个密码是我需要的！。。。非常感谢！！！。。。
 
 

Tharwat 发表于 2022-7-6 03:03:11

 
随时欢迎你。

pBe 发表于 2022-7-6 03:09:51

 
难道没有两组线可供选择吗，上面的白线和下面的红线？

查看完整版本: 连接终点线-crea