mdbdesign 发表于 2022-7-6 07:19:45

转换单个字符i

将pdf转换为dxf后，所有转换的文本显示为单个字符（如图所示）。有没有办法使用lisp将其转换回单词和句子？

BIGAL 发表于 2022-7-6 07:32:40

可以这样做，只需制作一个字符及其x插入位置的“列表”x的原因是它们可能没有按照查看的顺序创建，因此您的列表必须反映查看时的连续字符串，然后您可以使用字符之间的距离因子来暗示一个空格，因为空格不存在。倾斜文本？？
 
快速思考文本非perp使用左下边界框点，而不是插入pt来计算顺序。

Tharwat 发表于 2022-7-6 07:38:20

试试这个马瑞克。
 

(defun c:GatherTexts (/ ss i sn e lst l st)
;;;;;            Tharwat 01. Nov. 2012            ;;;;;
;;;;;      gathering TEXT entities all together in      ;;;;;
;;;;;      the first left entity from the selection set    ;;;;;
(or acdoc (setq acdoc (vla-get-activedocument (vlax-get-acad-object))))

(if (setq ss (ssget "_:L" '((0 . "TEXT"))))
   (progn (repeat (setq i (sslength ss))
            (setq sn (ssname ss (setq i (1- i))))
            (setq e (entget sn))
            (setq lst (cons (list (cdr (assoc 10 e)) (cdr (assoc 1 e)) sn) lst))
          )
          (setq l (vl-sort lst '(lambda (a b) (< (car (car a)) (car (car b))))))
          (setq st (apply 'strcat (mapcar 'cadr l)))
          (vla-StartUndoMark acdoc)
          (if (entmod (subst (cons 1 st) (assoc 1 (entget (caddr (car l)))) (entget (caddr (car l)))))
            (progn (setq l (reverse l)) (setq l (vl-remove (last l) l)) (mapcar 'entdel (mapcar 'caddr l)))
          )
          (vla-EndUndomark acdoc)
   )
   (princ)
)
(princ)
)

mdbdesign 发表于 2022-7-6 07:44:50

如果你是Tharwat，它工作得很好，但只适用于水平和倾斜文本。如果文字是垂直的：则将其反转。我不知道这是选择方式的问题（我想我尝试了所有方法）还是需要为代码做些什么。
如果您愿意，可以使用一个示例dwg进行测试。
测验图纸

Tharwat 发表于 2022-7-6 07:50:07

很抱歉造成混淆，这是因为我只编写了水平文本的代码，所以现在试试。
 

(defun c:Test (/ ss i sn e lst l st p r)
;;;;;            Tharwat 01. Nov. 2012            ;;;;;
;;;;;      gathering TEXT entities all together in      ;;;;;
;;;;;      the first left entity from the selection set    ;;;;;
(or acdoc (setq acdoc (vla-get-activedocument (vlax-get-acad-object))))
(if (setq ss (ssget "_:L" '((0 . "TEXT"))))
   (progn (repeat (setq i (sslength ss))
            (setq sn (ssname ss (setq i (1- i))))
            (setq e (entget sn))
            (setq lst (cons (list (cdr (assoc 10 e)) (cdr (assoc 1 e)) sn) lst))
          )
          (setq l (vl-sort lst '(lambda (a b) (< (car (car a)) (car (car b))))))
          (setq st (apply 'strcat (mapcar 'cadr l)))
          (setq p (mapcar 'car (mapcar 'car lst)))
          (foreach x p
            (if (equal x (car p))
            (setq r (cons x r))
            )
          )
          (vla-StartUndoMark acdoc)
          (if (eq (length r) (length p))
            (progn (setq st (vl-list->string (reverse (vl-string->list st))))
                   (if (entmod (subst (cons 1 st) (assoc 1 (entget (caddr (last l)))) (entget (caddr (last l)))))
                     (progn (setq l (reverse l)) (setq l (vl-remove (car l) l)) (mapcar 'entdel (mapcar 'caddr l)))
                   )
            )
            (if (entmod (subst (cons 1 st) (assoc 1 (entget (caddr (car l)))) (entget (caddr (car l)))))
            (progn (setq l (reverse l)) (setq l (vl-remove (last l) l)) (mapcar 'entdel (mapcar 'caddr l)))
            )
          )
          (vla-EndUndomark acdoc)
   )
   (princ)
)
(princ)
)

mdbdesign 发表于 2022-7-6 07:53:10

塔瓦，你是个完美的人。
我想为没有提及各种文本旋转而道歉。
干得好，非常感谢。我真的很感激。

Tharwat 发表于 2022-7-6 07:59:53

 
听到这个消息我很高兴。
 
非常欢迎你，马瑞克。

Lee Mac 发表于 2022-7-6 08:11:58

这是我的版本：
上述应正确处理在任何旋转时对齐的字符。
 
使用文件中的示例：
 

mdbdesign 发表于 2022-7-6 08:16:38

另一个很棒的。谢谢你，李。现在我可以一次选中所有项目，一次完成。完美的非常感谢你。

Lee Mac 发表于 2022-7-6 08:20:22

 
谢谢你，马瑞克，不客气。
页: [1]
查看完整版本: 转换单个字符i