rodrigo_sjc_sp 发表于 2022-7-6 07:25:44

Poliline闪烁

有没有办法用3种可选颜色设置多段线？
 
例如：颜色（黄色、红色、绿色）
 
多段线在1秒后变为黄色，在1秒后变为红色
变成绿色，绿色的一端在一个无限的循环中变回黄色？
 
我需要的是提请大家注意设计中有缺陷的多段线，并考虑设置一种或多种颜色，让它们在多段线之间交替。

rodrigo_sjc_sp 发表于 2022-7-6 07:37:47

有没有办法在LISP中创建一个计时器，它在1秒内执行命令以更改颜色？
 
需要更多的控制定时器，因为一旦你看到问题，我需要停止它，并设置一个中性色。

Lee Mac 发表于 2022-7-6 07:55:10

(defun c:flash ( / *error* cmd col ent enx old )
   (defun *error* ( m )
       (if old (entmod (append ent old)))
       (if cmd (setvar 'cmdecho cmd))
       (princ)
   )         
   (if (setq ent (car (entsel)))
       (progn
         (setq enx (entget ent)
               old (list (cond ((assoc 62 enx)) ('(62 . 256))))
               cmd (getvar 'cmdecho)
               col 2
         )
         (setvar 'cmdecho 0)
         (while (= 5 (car (grread t 13 1)))
               (entmod (append enx (list (cons 62 (setq col (1+ (- 2 col)))))))
               (command "_.delay" 150)
         )
         (entmod (append enx old))
         (setvar 'cmdecho cmd)
       )
   )
   (princ)
)

rodrigo_sjc_sp 发表于 2022-7-6 08:08:46

谢谢李，
 
 
代码正是我需要的。
 
 

Tharwat 发表于 2022-7-6 08:18:17

 
这些人花时间只是为了帮助你，而你甚至没有向他们眨眼。
 
http://www.cadtutor.net/forum/showthread.php?73287-查找未闭合的多段线

Lee Mac 发表于 2022-7-6 08:29:28

 
不客气。
页: [1]
查看完整版本: Poliline闪烁