如何使用Lisp“激活”
大家好，我想知道是否有任何方法可以使用AutoLisp“激活”选定的视口（而不是VLisp，因为我根本不知道任何VLisp！！！）
例如，如果我在图纸空间中的视口上绘制一个矩形，并且我想将该矩形转移到模型空间中，我会使用CAD命令“chspace”，但随后我需要单击特殊视口，以便矩形到达正确的位置。此外，如果我想将视口图像设置为特定比例，例如1:20，我还必须单击视口并键入“zoom”“1/20xp”。
我不知道如何使用AutoLisp“激活”选定的视口。
非常感谢你 每个视口的ID存储在DXF代码69中（使用ENTGET函数列出）。
接下来，使用CVPORT系统变量激活特定视口。
(command "_MSPACE")
(setvar "CVPORT" 2) 还有VPORTS函数，它将列出布局中定义的视口（1始终是图纸空间）。
;;; Cycle Through Viewports (05-VI-2012)
(defun c:CTV( / oldCmdEcho listVPorts itemVPort )
(vl-load-com)
(setq oldCmdEcho (getvar "CMDECHO"))
(setvar "CMDECHO" 0)
(if (/= (getvar "CTAB") "Model")
(progn
(setq listVPorts (vl-sort (vports) '(lambda(v1 v2) (< (car v1) (car v2)))))
(if (> (length listVPorts) 1)
(progn
(command "_MSPACE")
(foreach itemVPort (cdr listVPorts)
(setvar "CVPORT" (car itemVPort))
(getkword "\nPress <ENTER> to go to next viewport")
)
(command "_PSPACE")
)
(prompt "\nThere are no viewports defined in this Layout!")
)
)
(prompt "\nThis routine works only in Layout!")
)
(setvar "CMDECHO" oldCmdEcho)
(princ)
) 太好了，它应该能解决我的问题！！！
非常感谢Msasu 不客气！ 另一种方法：
(defun c:vpon ( / d s )
(vl-load-com)
(if (setq s (ssget "_+.:S:E:L" '((0 . "VIEWPORT"))))
(progn
(setq d (vla-get-activedocument (vlax-get-acad-object)))
(vla-put-mspace d :vlax-true)
(vla-put-activeviewport d (vlax-ename->vla-object (ssname s 0)))
)
)
(princ)
)
以及“停用”：
(defun c:vpoff ( )
(vla-put-mspace (vla-get-activedocument (vlax-get-acad-object)) :vlax-false)
(princ)
)
页:
[1]