社区 › Auto Lisp › 直线为pi时插入圆

BrianTFC 发表于 2022-7-6 08:14:51

直线为pi时插入圆

大家好，
 
我想知道是否有一个lisp例程，当你选择一条线时，它会放在两行中心之间的圆圈中，每行距离两端6英寸？我附上了一个文件，显示了我在寻找什么。
 
谢谢
布瑞恩

Tharwat 发表于 2022-7-6 08:24:20

这是否意味着要在选定线的中心插入一个名为“孔”的块？

BrianTFC 发表于 2022-7-6 08:26:26

不。我想要它做的是画圆圈。

Tharwat 发表于 2022-7-6 08:35:14

像这样的事情？
 

(defun c:TesT (/ ss i sn)
(princ "\n Select lines :")
(if (setq ss (ssget '((0 . "LINE"))))
   (repeat (setq i (sslength ss))
   (setq sn (ssname ss (setq i (1- i))))
   (entmake (list '(0 . "CIRCLE")
                  (cons 10
                        (mapcar (function (lambda (a b)
                                              (/ (+ a b) 2.)
                                          )
                                  )
                                  (cdr (assoc 10 (entget sn)))
                                  (cdr (assoc 11 (entget sn)))
                        )
                  )
                  '(40 . 1.0)
            )
   )
   )
   (princ "\n Nothing selected or not line(s) *** ")
)
(princ)
)

Tharwat 发表于 2022-7-6 08:39:26

我想这就是。。。。。
 

(defun c:TesT (/ ss i sn p1 p2)
;;; Tharwat 22. Feb. 2012 ;;;
(princ "\n Select lines :")
(if (setq ss (ssget '((0 . "LINE"))))
   (repeat (setq i (sslength ss))
   (setq sn (ssname ss (setq i (1- i))))
   (entmake
       (list
         '(0 . "CIRCLE")
         (cons 10
               (polar (setq p1 (cdr (assoc 10 (entget sn))))
                      (angle p1 (setq p2 (cdr (assoc 11 (entget sn)))))
                      147.
               )
         )
         '(40 . 3.0)
       )
   )
   (entmake (list '(0 . "CIRCLE")
                  (cons 10 (polar p2 (angle p2 p1) 147.))
                  '(40 . 3.0)
            )
   )
   )
   (princ "\n Nothing selected or not line(s) *** ")
)
(princ)
)

BrianTFC 发表于 2022-7-6 08:45:23

没有。但那很酷。。我需要它把两个圆圈6英寸，从两端的蓝色线“当挑选”在我的画，并有他们之间的蓝色和绿色的中心线。

BIGAL 发表于 2022-7-6 08:50:36

对代码进行几个简单的更改
 

(polar p2 (angle p2 p1) 147.)) change the 147 to 6"
(polar p1 (angle p1 p2) 147.)) need to repeat entmake for other end

pBe 发表于 2022-7-6 08:57:07

两端距离6英寸？
什么决定了圆的半径？

BrianTFC 发表于 2022-7-6 09:03:02

这是Tharwat编写的代码，在Bigal的帮助下，我能够像我需要的那样将孔设置为距离线条末端6“，但我需要做什么更改才能使圆位于线条上方3/8”。
 
 

(defun c:wh (/ ss i sn p1 p2)
;;; Tharwat 22. Feb. 2012 ;;;
(princ "\n Select lines :")
(if (setq ss (ssget '((0 . "LINE"))))
(repeat (setq i (sslength ss))
(setq sn (ssname ss (setq i (1- i))))
(entmake
(list
'(0 . "CIRCLE")
(cons 10
(polar (setq p1 (cdr (assoc 10 (entget sn))))
(angle p1 (setq p2 (cdr (assoc 11 (entget sn)))))
6
)
)
'(40 . 0.1875)
)
)
(entmake (list '(0 . "CIRCLE")
(cons 10 (polar p2 (angle p2 p1) 6))
'(40 . 0.1875)
)
)
)
(princ "\n Nothing selected or not line(s) *** ")
)
(princ)
)

David Bethel 发表于 2022-7-6 09:06:52

我想我理解：

(defun c:cirend (/ ss en ed p10 p11 c10 c11 ang pan)
(and (setq ss (ssget '((0 . "LINE"))))
      (while (setq en (ssname ss 0))
             (setq ed (entget en)
                   p10 (cdr (assoc 10 ed))
                   p11 (cdr (assoc 11 ed))
                   c10 (polar p10 (angle p10 p11) 6)
                   c11 (polar p11 (angle p11 p10) 6)
                   ang (angle p10 p11)
                   pan (if (< (* pi 0.5) ang (* pi 1.5))
                           (+ ang (* pi -0.5))
                           (+ ang (* pi0.5)))
                   c10 (polar c10 pan 0.375)
                   c11 (polar c11 pan 0.375))
             (entmake (list (cons 0 "CIRCLE")(cons 10 c10)(cons 40 0.1875)))
             (entmake (list (cons 0 "CIRCLE")(cons 10 c11)(cons 40 0.1875)))
             (ssdel en ss)))
(prin1))

 
 
-大卫

查看完整版本: 直线为pi时插入圆