josemukalel 发表于 2022-7-6 11:05:48

如何选择过高尺寸

如何选择过高的维度？qselect在我的autocad中不工作

MMS 发表于 2022-7-6 11:15:04

请试试这个，
 
(prompt "Ketik chkd untuk menjalankan program!")
(defun c:chkd (/ cd DimSel Pengulangan cnt Sdat EntDat DimGan )
(setq DimSel (ssget "_X" (list (cons 0 "Dimension")))); pemilihan objek khusus dimensi
(setq Pengulangan (sslength DimSel)); menghitung jumlah objek yang terpilih
(Setq cnt -1); membuat counter
(setq cd (ssadd))
;----------
(repeat Pengulangan
(setq cnt(1+ cnt))
(setq Sdat (ssname DimSel cnt)); mengambil ename
(setq EntDat (entget Sdat))
(setq DimGan (cdr(assoc 1 EntDat))); mencari data dimensi yang diganti
(if (/= DimGan "")
(ssadd Sdat cd )

); if
); repeat
(command "select" cd)
(princ)
);defun
(princ)

 
当做
 
非洲RI

josemukalel 发表于 2022-7-6 11:21:38

很好，非常感谢

asos2000 发表于 2022-7-6 11:34:27

多媒体信息服务
谢谢你的Lisp程序
你能把这些句子从你的母语郎翻译成英语吗？

MMS 发表于 2022-7-6 11:38:09

 
不客气。
 
当做
 
非洲RI

MMS 发表于 2022-7-6 11:48:37

 
对不起，我会试着用英语翻译。
 
(prompt "Type CHKD for running program!")
(defun c:chkd (/ cd DimSel Pengulangan cnt Sdat EntDat DimGan )
(setq DimSel (ssget "_X" (list (cons 0 "Dimension")))); Selection set for Dimension
(setq Pengulangan (sslength DimSel)); calculating the selected object
(Setq cnt -1); Counter
(setq cd (ssadd))
;----------
(repeat Pengulangan
(setq cnt(1+ cnt))
(setq Sdat (ssname DimSel cnt)); Get Ename
(setq EntDat (entget Sdat))
(setq DimGan (cdr(assoc 1 EntDat))); Searching Override Dimension
(if (/= DimGan "")
(ssadd Sdat cd )

); if
); repeat
(command "select" cd)
(princ)
);defun
(princ)

 
我来自印度尼西亚，所以有时我会使用巴哈萨语来创建简单的代码。
 
当做
 
非洲RI

Lee Mac 发表于 2022-7-6 11:56:55


(defun c:dsel nil
(sssetfirst nil
   (ssget "_X" '((0 . "DIMENSION") (-4 . "<NOT") (1 . "") (-4 . "NOT>")))
)
(princ)
)

gile 发表于 2022-7-6 11:59:27

李，
 
(sssetfirst nil (ssget "_X" '((0 . "DIMENSION") (1 . "*?*"))))

Lee Mac 发表于 2022-7-6 12:11:55

不错的一个Gile
页: [1]
查看完整版本: 如何选择过高尺寸