社区 › Auto Lisp › 请求：查找所有尺寸w

ILoveMadoka 发表于 2022-7-6 11:49:24

请求：查找所有尺寸w

我甚至不知道从哪里开始这一点，我相信有人可以代码这之前，我甚至可以研究它。
 
我想在一张画里找到所有的尺寸都有一个封边，然后把它们的颜色改成洋红色。
 
我们很难让绘图者正确地绘制，而且没有手动检查每个维度，我希望能够看到他们在哪里“获得了创造性自由”
 
虽然我想问一下这是否困难，但我知道目前的公司没有
发现许多请求很难。
 
谢谢你们为我和其他人所做的一切。

gile 发表于 2022-7-6 12:05:50

你好
 
像这样的？
 
(defun c:test (/ ss n ent elst)
(if (setq n0
         ss (ssget "_X"
                     '((0 . "DIMENSION") (-4 . "<not") (1 . "") (-4 . "not>"))
            )
   )
   (while (setq ent (ssname ss n))
   (setq elst (entget ent) n (1+ n))
   (entmod (if (not (assoc 62 elst))
               (append elst '((62 . 6)))
               (subst '(62 . 6) (assoc 62 elst) elst)
             )
   )
   )
)
(princ)
)

lpseifert 发表于 2022-7-6 12:09:24

这是我的尝试

(defun c:test (/ ss1 sslen cnt obj tst)
(vl-load-com)
(setq ss1 (ssget "x" '((0 . "*DIMENSION*")))
   sslen (sslength ss1)
       cnt 0)
(repeat sslen
   (setq obj (vlax-ename->vla-object (ssname ss1 cnt))
         tst (vlax-get obj 'TextOverride))
    (if (vl-string->list tst)
   (vlax-put-property obj 'Color 6)
      )
   (setq cnt (1+ cnt))
)
(princ)
)

paulmcz 发表于 2022-7-6 12:22:48

嗨，吉尔，
 
如果覆盖文本包括，您将如何从选择中筛选该维度？
 
谢谢
保罗。

ILoveMadoka 发表于 2022-7-6 12:27:11

两者都很好！！
 
非常感谢！！！

ILoveMadoka 发表于 2022-7-6 12:38:47

我测试了它，覆盖就是覆盖。
是否有人使用实际维度或并添加注释
它仍处于标记状态。
 
*完美*

gile 发表于 2022-7-6 12:46:40

(ssget "_X"
      '((0 . "DIMENSION")
      (-4 . "<not")
      (-4 . "<or")
      (1 . "")
      (1 . "*<>*")
      (-4 . "or>")
      (-4 . "not>")
       )
)
 
或者，更神秘一点：
(ssget "_X"
      '((0 . "DIMENSION") (-4 . "<not") (1 . "") (-4 . "not>") (1 . "~*<>*"))
)

paulmcz 发表于 2022-7-6 12:49:54

太好了，吉尔，非常感谢。我要花上一辈子的时间才能弄明白如何与这些野性人物合作。
再次感谢。
保罗。

查看完整版本: 请求：查找所有尺寸w