Lee Mac 发表于 2022-7-6 14:14:04

快速断圆

我突然想到了一个主意，因为我记得必须在图纸上画很多圆圈来显示隐藏线等，所以这应该会让你们的生活更轻松
 

(defun c:cBrk (/ *error* vl ov p1 ent p2 aDef flag ent)
(vl-load-com)

(defun *error* (msg)
   (if ov (mapcar 'setvar vl ov))
   (if (not
         (wcmatch
         (strcase msg) "*BREAK,*CANCEL*,*EXIT*"))
   (princ (strcat "\n<< Error: " msg " >>")))
   (princ))

(setq vl '("CMDECHO" "OSMODE")
       ov (mapcar 'getvar vl))
(or (eq 512 (logand 512 (getvar 'OSMODE)))
   (setvar 'OSMODE (+ (getvar 'OSMODE) 512)))

(while
   (progn
   (setq p1 (getpoint "\nSelect Point on Circle: "))
   (cond ((vl-consp p1)
            (if (and (setq ent (car (nentselp p1)))
                     (not (eq "CIRCLE" (cdr (assoc 0 (entget ent))))))
            (princ "\n** Point does not lie on a Circle **")))
         (t (princ "\n** No Point Selected**")))))

(while
   (progn
   (setq p2 (getpoint "\nSelect Second Point to Break: "))
   (cond ((vl-consp p2)
            (cond ((eq p1 p2)
                   (princ "\n** Points must be distinct **"))
                  (t (setq p2 (vlax-curve-getClosestPointto ent p2)) nil)))
         (t (princ "\n** No Point Selected **")))))

(setq cen (cdr (assoc 10 (entget ent))))
(repeat 2
   (setq aDef
   (list
       (cons 100 "AcDcEntity")
       (cons 0 "ARC")))
   (foreach dxf '(8 10 40 210)
   (setq aDef
       (cons
         (assoc dxf (entget ent)) aDef)))
   (setq aDef
   (append
       (reverse aDef)
         (list
         (cons 50
             (if flag
               (angle cen p1) (angle cen p2)))
         (cons 51
             (if flag
               (angle cen p2) (angle cen p1))))))
   (entmake aDef)
   (setq flag t))

(entdel ent)
(mapcar 'setvar vl ov)
(princ))
      

CADMASTER1128 发表于 2022-7-6 14:17:29

我觉得有人在家里很无聊！

Lee Mac 发表于 2022-7-6 14:23:25

 
只有在晚上没有电视的时候

ReMark 发表于 2022-7-6 14:25:48

李：你的主要商业计划是免费赠送你所有的代码吗？你打算做什么工作？

CADMASTER1128 发表于 2022-7-6 14:28:46

 
他提出一个观点，CADTutor会员应该享受五折优惠，然后再收取超低价。您可以选择测试人员（您相信他们不会免费提供）来测试LISP。

Lee Mac 发表于 2022-7-6 14:32:11

 
我知道马克：眨眼：
 
我想即使我开始为代码收费，其他人也会免费提供。

ReMark 发表于 2022-7-6 14:34:09

那么你决定要比其他人贡献更多的代码，对吗？该死！你是个主谋。你需要会见唐纳德·特朗普。

Lee Mac 发表于 2022-7-6 14:38:54

 
如果这不是讽刺，那么我不知道LISP…：眨眼：

ReMark 发表于 2022-7-6 14:40:17

我对李的讽刺不屑一顾。

Lee Mac 发表于 2022-7-6 14:44:39

 
谢谢，伙计，你自己也不错
页: [1] 2
查看完整版本: 快速断圆