X-Y尺寸
有没有一种方法可以同时标注两点之间的x-y长度，而不必每次都进行线性标注？我不需要坐标。我在找长度。
可能是lisp或宏？
谢谢 最简单的方法是一个尺寸样式，你可以关闭很多东西，所以可以有一个样式，这是箭头，但它会使用dim-align命令，但一个小的lisp可以解决这一问题。
很好的一个尝试自己。换句话说，pick pt1，pick pt2，command dim align pt1 pt2 all done 如果我知道如何编写lisp代码就好了。 Robwell，
这将对所选内容的x和y进行尺寸标注，不确定它是否是您所需要的。
Tharwat很友善地写了这封信，所以请确保你不要删除他的名字。
(defun c:kk (/ s i l r l1 r1 lx ly rx ry a b c d p1 p2 p3)
;; Tharwat 28. Nov. 2013 ;;
(if (setq s (ssget '((-4 . "<NOT")
(-4 . "<OR")
(0 . "XLINE")
(0 . "RAY")
(0 . "*DIMENSION")
(-4 . "OR>")
(-4 . "NOT>")
)
)
)
(progn
(repeat (setq i (sslength s))
(vla-GetBoundingBox
(vlax-ename->vla-object (ssname s (setq i (1- i))))
'l
'r
)
(setq l1 (vlax-safearray->list l)
r1 (vlax-safearray->list r)
lx (cons (car l1) lx)
ly (cons (cadr l1) ly)
rx (cons (car r1) rx)
ry (cons (cadr r1) ry)
)
)
(setq a(apply 'min lx)
b(apply 'min ly)
c(apply 'max rx)
d(apply 'max ry)
p1 (list c d)
p2 (list a d)
p3 (list c b)
)
(command "._dimlinear"
"_none"
p1
"_none"
p2
"_none"
(polar p1 (* pi 0.5) (/ (distance p1 p2) 10.))
)
(command "._dimlinear"
"_none"
p1
"_none"
p3
"_none"
(polar p1 0. (/ (distance p1 p3) 10.))
)
)
)
(princ)
)
(vl-load-com) 这非常有效。我能够操纵几个数字，使偏移量稍微远一点。我希望我知道的唯一一件事是，用这个Lisp程序的Lisp程序把dims放在相反的一边。不过我还是可以用的。非常感谢。
如果有人知道如何操作DIM的位置放置，那将非常棒。
再次感谢，Dahzee。
如果我了解您想要什么以及代码说明了什么，您可以将原点移动到选择框的另一侧。换句话说
p1（列表c和d）
变成
p1（列表a和b） 这是正确的方向，谢谢。它并没有完全按照我喜欢的方式放置它们，所以我会用它来找到正确的位置。
页:
[1]