旋转到对齐的dim LISP是
早上好我正在看我公司的一个旧的LISP，它会非常有用，但由于某种原因，当它用旋转的维度替换对齐的维度时，新的维度会有点颠簸。谁能看看这个问题是否有一个简单的解决方案？
我希望新维度完全模仿前一个维度的位置，而不是将其撞坏。也许这与文本放置点有关？不确定。
提前感谢！
(defun dtr (a) (* pi (/ a 180.0)))
DTR
(defun c:A2R (/ ss Ent EntData Pt1 Pt2 Pt3 ocmd omode olay odim)
; Redraw dimension that were drawn as aligned as rotated on correct layer, and with correct dimension style.
(setq ocmd (getvar "cmdecho"))
(setvar "cmdecho" 0)
(command "_.undo" "_end")
(command "_.undo" "_begin")
(setq old_omode (getvar "osmode"))
(setvar "osmode" 0)
(setq olay (getvar "clayer"))
(setq odim (getvar "dimstyle"))
(if (setq ss (ssget '((0 . "DIMENSION"))))
(while (setq Ent (ssname ss 0))
(setq EntData (entget Ent))
(if (not (member '(100 . "AcDbRotatedDimension") EntData))
(progn
(setq Pt1 (cdr (assoc 13 EntData)))
(setq Pt2 (cdr (assoc 14 EntData)))
(setq Pt3 (cdr (assoc 11 EntData)))
(if (< (car Pt1) (car Pt2))
(command "_.ucs"
"_3"
Pt1
Pt2
(polar Pt1
(+ (DTR 90) (angle Pt1 Pt2))
5
)
)
(command "_.ucs"
"_3"
Pt2
Pt1
(polar Pt2
(+ (DTR 90) (angle Pt2 Pt1))
5
)
)
)
(setvar "clayer" (cdr (assoc 8 EntData)))
(command "_.dimstyle" "_r" (cdr (assoc 3 EntData)))
(entdel Ent)
(command "_.dim"
"_horizontal"
(trans Pt1 0 1)
(trans Pt2 0 1)
(trans
Pt3
0
1
)
""
"_exit"
)
(command "_.ucs" "_p")
)
)
(ssdel Ent ss)
)
)
(command "_.dimstyle" "_r" odim)
(command "_.undo" "_end")
(setvar "clayer" olay)
(setvar "osmode" old_omode)
(setvar "cmdecho" ocmd)
(princ)
) 也许有一种方法可以专门保持文本位置x和y？这就是每次发生的变化 您应该使用组码10（定义点），而不是使用组码11（文本的中点）。 这太完美了！我尝试了其他一些组码，但没有成功。这个就是我需要的。非常感谢！！
页:
[1]