NBC 发表于 2022-7-5 16:34:55

导出文本插入点t

有人知道如何将文本的插入点（以及文本本身的内容）导出到excel文件中吗？（xls或.csv就可以了）
 
非常感谢大家的帮助。

NBC 发表于 2022-7-5 17:09:57

没关系，我从http://www.cadtutor.net/forum/showthread.php?t=18351

Lee Mac 发表于 2022-7-5 17:22:55

可能较短的路径：
 

(defun c:ttx(/ ss xlApp xlCells row col i)
(vl-load-com)
(if (setq ss (ssget '((0 . "*TEXT"))))
   (progn
   (setq xlApp   (vlax-get-or-create-object "Excel.Application")
         xlCells (vlax-get-property
                     (vlax-get-property
                     (vlax-get-property
                         (vlax-invoke-method
                           (vlax-get-property xlApp "Workbooks")
                           "Add") "Sheets") "Item" 1) "Cells") row 0 col 1)
   (vla-put-visible xlApp :vlax-true)
   (foreach y
       (mapcar '(lambda (x / iPt)
                  (setq iPt (vlax-get x 'InsertionPoint))
                  (list (vla-get-TextString x)
                        (rtos (car iPt) 2 2)
                        (rtos (cadr iPt) 2 2)
                        (rtos (caddr iPt) 2 2)))
       (mapcar 'vlax-ename->vla-object
               (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss)))))
       (if (> row 65536) (setq col 5))
       (setq i -1 row (1+ row))
       (mapcar
         (function
         (lambda (x)
             (vlax-put-property xlCells "Item" row
               (+ col (setq i (1+ i))) x))) y))))
(mapcar 'vlax-release-object (list xlApp xlCells))
(princ))

evylrat 发表于 2022-7-5 17:35:44

李，刚刚找到了这个帖子和你附加的LISP。非常好，谢谢！由于您的更新标题栏和选项卡列表LISP，我很快重命名了近100个图形（有人遗漏了一些按顺序排列的图形）
页: [1]
查看完整版本: 导出文本插入点t