乐筑天下

搜索
欢迎各位开发者和用户入驻本平台 尊重版权,从我做起,拒绝盗版,拒绝倒卖 签到、发布资源、邀请好友注册,可以获得银币 请注意保管好自己的密码,避免账户资金被盗
查看: 25|回复: 1

如何用ActiveX创建一个图层?

[复制链接]
cag

87

主题

265

帖子

10

银币

中流砥柱

Rank: 25

铜币
613
发表于 2003-6-27 11:07:00 | 显示全部楼层 |阅读模式
我想用ActiveX方法创建一个图层,却发现并没有vla-addlayer函数?是真的吗?怎么办?
回复

使用道具 举报

26

主题

3072

帖子

10

银币

社区元老

Rank: 75Rank: 75Rank: 75

铜币
3177
发表于 2003-6-27 11:19:00 | 显示全部楼层
;以下是加载删除线型,添加删除图层,并设定其颜色,
(vl-load-com)
(defun listline(/ adoc ltps n i ltp1)
  (setq adoc (vla-get-activedocument (vlax-get-acad-object)))
  (setq ltps (vla-get-linetypes adoc))
  (setq n (vla-get-count ltps))
  (setq i 3)
  (repeat (- n 3)
    (setq ltp1 (vla-item ltps i))
    (princ "\n")
    (print (vla-get-name ltp1))
    (princ "\n")
    (setq i (1+ i))
  )
  (princ)
)
(defun c:loadline(/ adoc msp ltps lname)
  (setq lname (getstring "输入需要添加的线型:"))
  (setq adoc (vla-get-activedocument (vlax-get-acad-object)))
  (setq ltps (vla-get-linetypes adoc))
  (setq ltp (vl-catch-all-apply 'vla-load (list ltps lname "acadiso.lin")))
  (if (vl-catch-all-error-p ltp)
    (princ "此线型已存在!")
    (princ)
  )
  (princ)
)
(defun c:delline(/ adoc msp ltps ltp lname)
  (setq adoc (vla-get-activedocument (vlax-get-acad-object)))
  (setq ltps (vla-get-linetypes adoc))
  (setq lname (getstring "输入需要删除的线型:"))
  (if (= lname "") (listline))
  (while (= lname "")
    (setq lname (getstring "输入需要删除的线型[List]:"))
    (if (= (strcase lname 0) "l") (progn (listline) (setq lname "")))
  )
  (setq ltp (vl-catch-all-apply 'vla-item (list ltps lname)))
  (if (vl-catch-all-error-p ltp)
    (princ "没有此线型!")
    (vla-delete ltp)
  )
  (princ)
)
(defun c:dellayer(/ adoc msp ltps ltp lname)
  (setq adoc (vla-get-activedocument (vlax-get-acad-object)))
  (setq ltps (vla-get-layers adoc))
  (setq lname (getstring "输入需要删除的图层:"))
  (if (= lname "") (listlayer))
  (while (= lname "")
    (setq lname (getstring "输入需要删除的图层[List]:"))
    (if (= (strcase lname 0) "l") (progn (listlayer) (setq lname "")))
  )
  (setq ltp (vl-catch-all-apply 'vla-item (list ltps lname)))
  (if (vl-catch-all-error-p ltp)
    (princ "没有此图层!")
    (vla-delete ltp)
  )
  (princ)
)
(defun listlayer(/ adoc ltps n i ltp1)
  (setq adoc (vla-get-activedocument (vlax-get-acad-object)))
  (setq ltps (vla-get-layers adoc))
  (setq n (vla-get-count ltps))
  (setq i 0)
  (repeat (- n 0)
    (setq ltp1 (vla-item ltps i))
    (princ "\n")
    (print (vla-get-name ltp1))
    (princ "\n")
    (setq i (1+ i))
  )
)
(defun Newlayer(lname lcolor / layer layers adoc)
  (setq adoc (vla-get-activedocument (vlax-get-acad-object)))
  (setq layers (vla-get-layers adoc))
  (setq layer (vl-catch-all-apply 'vla-item (list layers lname)))
  (if (vl-catch-all-error-p layer)
    (progn
      (setq layer (vla-add layers lname))
      (vla-put-color layer lcolor)
    )
  )
  (vla-put-ActiveLayer adoc layer)
  (princ)
)
回复

使用道具 举报

发表回复

您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

  • 微信公众平台

  • 扫描访问手机版

  • 点击图片下载手机App

QQ|关于我们|小黑屋|乐筑天下 繁体中文

GMT+8, 2025-7-3 17:53 , Processed in 2.335037 second(s), 56 queries .

© 2020-2025 乐筑天下

联系客服 关注微信 帮助中心 下载APP 返回顶部 返回列表