乐筑天下

搜索
欢迎各位开发者和用户入驻本平台 尊重版权,从我做起,拒绝盗版,拒绝倒卖 签到、发布资源、邀请好友注册,可以获得银币 请注意保管好自己的密码,避免账户资金被盗
查看: 103|回复: 3

使用孵化创建块

[复制链接]

12

主题

175

帖子

77

银币

初露锋芒

Rank: 3Rank: 3Rank: 3

铜币
149
发表于 2017-11-15 19:25:16 | 显示全部楼层 |阅读模式
我正在尝试帮助一位朋友使用此代码。他们可以使用2个拾取的点绘制得克萨斯州国旗,但希望将结果进行一个块。我想不出来。
  1. Option Explicit
  2. Public Sub DrawTexasFlagOp()
  3. Dim PT1 As Variant
  4. Dim PT2 As Variant
  5. Dim pntLL(0 To 2) As Double
  6. Dim pntLR(0 To 2) As Double
  7. Dim pntUL(0 To 2) As Double
  8. Dim pntUR(0 To 2) As Double
  9. Dim pntLRBlue(0 To 2) As Double
  10. Dim pntURBlue(0 To 2) As Double
  11. Dim vertDist As Double
  12. Dim horzDist As Double
  13. Dim pntRW_Left(0 To 2) As Double
  14. Dim pntRW_Right(0 To 2) As Double
  15. Dim circleDiameter As Double
  16. Dim cntPnt(0 To 2) As Double
  17. Dim cir As AcadCircle
  18. Dim starTopPoint(0 To 2) As Double
  19. ' star leg length @ unit circle of 1 = .7265
  20. ' starlegLength is variable
  21. Dim starLegLen As Double
  22. Dim starLegStart As Variant
  23. Dim starLegEnd As Variant
  24. PT1 = ThisDrawing.Utility.GetPoint(, "Pick lower left corner of Flag")
  25. vertDist = ThisDrawing.Utility.GetDistance(PT1, vbCr & "Pick distance for vertical")
  26. horzDist = (vertDist / 2) * 3
  27. pntLL(0) = PT1(0) 'X value
  28. pntLL(1) = PT1(1) 'Y value
  29. pntUL(0) = PT1(0)
  30. pntUL(1) = PT1(1) + vertDist
  31. pntLR(0) = PT1(0) + horzDist
  32. pntLR(1) = PT1(1)
  33. pntUR(0) = PT1(0) + horzDist
  34. pntUR(1) = PT1(1) + vertDist
  35. pntLRBlue(0) = pntLL(0) + (horzDist / 3)
  36. pntLRBlue(1) = pntLL(1)
  37. pntURBlue(0) = pntLL(0) + (horzDist / 3)
  38. pntURBlue(1) = pntLL(1) + vertDist
  39. pntRW_Left(0) = pntLRBlue(0)
  40. pntRW_Left(1) = pntLRBlue(1) + (vertDist / 2)
  41. pntRW_Right(0) = pntLR(0)
  42. pntRW_Right(1) = pntRW_Left(1)
  43. circleDiameter = (horzDist / 3) * 0.75
  44. cntPnt(0) = pntLL(0) + horzDist / 6
  45. cntPnt(1) = pntLL(1) + vertDist / 2
  46. starTopPoint(0) = cntPnt(0)
  47. starTopPoint(1) = cntPnt(1) + (circleDiameter / 2)
  48. starLegLen = 0.7265 * (circleDiameter / 2)
  49. Dim plineObjStar As AcadLWPolyline
  50. Dim pointsStar(0 To 21) As Double
  51. starLegStart = starTopPoint
  52. starLegEnd = ThisDrawing.Utility.PolarPoint(starLegStart, dtor(288), starLegLen)
  53. pointsStar(0) = starTopPoint(0)
  54. pointsStar(1) = starTopPoint(1)
  55. pointsStar(2) = starLegEnd(0)
  56. pointsStar(3) = starLegEnd(1)
  57. starLegStart = starLegEnd
  58. starLegEnd = ThisDrawing.Utility.PolarPoint(starLegStart, dtor(0), starLegLen)
  59. pointsStar(4) = starLegEnd(0)
  60. pointsStar(5) = starLegEnd(1)
  61. starLegStart = starLegEnd
  62. starLegEnd = ThisDrawing.Utility.PolarPoint(starLegStart, dtor(216), starLegLen)
  63. pointsStar(6) = starLegEnd(0)
  64. pointsStar(7) = starLegEnd(1)
  65. starLegStart = starLegEnd
  66. starLegEnd = ThisDrawing.Utility.PolarPoint(starLegStart, dtor(288), starLegLen)
  67. pointsStar(8) = starLegEnd(0)
  68. pointsStar(9) = starLegEnd(1)
  69. starLegStart = starLegEnd
  70. starLegEnd = ThisDrawing.Utility.PolarPoint(starLegStart, dtor(144), starLegLen)
  71. pointsStar(10) = starLegEnd(0)
  72. pointsStar(11) = starLegEnd(1)
  73. starLegStart = starLegEnd
  74. starLegEnd = ThisDrawing.Utility.PolarPoint(starLegStart, dtor(216), starLegLen)
  75. pointsStar(12) = starLegEnd(0)
  76. pointsStar(13) = starLegEnd(1)
  77. starLegStart = starLegEnd
  78. starLegEnd = ThisDrawing.Utility.PolarPoint(starLegStart, dtor(72), starLegLen)
  79. pointsStar(14) = starLegEnd(0)
  80. pointsStar(15) = starLegEnd(1)
  81. starLegStart = starLegEnd
  82. starLegEnd = ThisDrawing.Utility.PolarPoint(starLegStart, dtor(144), starLegLen)
  83. pointsStar(16) = starLegEnd(0)
  84. pointsStar(17) = starLegEnd(1)
  85. starLegStart = starLegEnd
  86. starLegEnd = ThisDrawing.Utility.PolarPoint(starLegStart, dtor(0), starLegLen)
  87. pointsStar(18) = starLegEnd(0)
  88. pointsStar(19) = starLegEnd(1)
  89. pointsStar(20) = starTopPoint(0)
  90. pointsStar(21) = starTopPoint(1)
  91. Dim mylayer As AcadLayer
  92. Set mylayer = ThisDrawing.Layers.Add("RED")
  93. mylayer.color = acRed
  94. Set mylayer = ThisDrawing.Layers.Add("WHITE")
  95. mylayer.color = acWhite
  96. Set mylayer = ThisDrawing.Layers.Add("BLUE")
  97. mylayer.color = acBlue
  98. Set mylayer = ThisDrawing.Layers.Item("RED")
  99. ThisDrawing.ActiveLayer = ThisDrawing.Layers.Item("0")
  100. Dim hatchObj As AcadHatch
  101. Dim hatchObj2 As AcadHatch
  102. Dim hatchObj3 As AcadHatch ' blue
  103. Dim hatchobj4 As AcadHatch
  104.   Dim patternName As String
  105.   Dim PatternType As Long
  106.   Dim bAssociativity As Boolean
  107.   ' Define the hatch
  108.   patternName = "SOLID"
  109.   PatternType = 0
  110.   bAssociativity = True
  111.   Set hatchObj = ThisDrawing.ModelSpace.AddHatch(PatternType, patternName, bAssociativity)
  112. Dim plineObj As AcadLWPolyline
  113.   Dim points(0 To 9) As Double
  114.     points(0) = pntRW_Left(0)
  115.     points(1) = pntRW_Left(1)
  116.     points(2) = pntRW_Right(0)
  117.     points(3) = pntRW_Right(1)
  118.     points(4) = pntUR(0)
  119.     points(5) = pntUR(1)
  120.     points(6) = pntURBlue(0)
  121.     points(7) = pntURBlue(1)
  122.     points(8) = pntRW_Left(0)
  123.     points(9) = pntRW_Left(1)
  124. Set plineObj = ThisDrawing.ModelSpace.AddLightWeightPolyline(points)
  125. plineObj.Closed = False
  126. Dim outerLoop As Variant
  127. Dim outerLoopArray(0) As Object
  128. Set outerLoopArray(0) = plineObj
  129. outerLoop = outerLoopArray
  130. hatchObj.AppendOuterLoop (outerLoop)
  131. hatchObj.Layer = "WHITE"
  132. hatchObj.Evaluate
  133. plineObj.Delete  ' white hatch polyline
  134. ThisDrawing.Regen True
  135. 'create red hatch pline
  136.     points(0) = pntRW_Left(0)
  137.     points(1) = pntRW_Left(1)
  138.     points(2) = pntRW_Right(0)
  139.     points(3) = pntRW_Right(1)
  140.     points(4) = pntLR(0)
  141.     points(5) = pntLR(1)
  142.     points(6) = pntLRBlue(0)
  143.     points(7) = pntLRBlue(1)
  144.     points(8) = pntRW_Left(0)
  145.     points(9) = pntRW_Left(1)
  146. Set plineObj = ThisDrawing.ModelSpace.AddLightWeightPolyline(points)
  147. plineObj.Closed = False
  148. Set outerLoopArray(0) = plineObj
  149. outerLoop = outerLoopArray
  150. Set hatchObj2 = ThisDrawing.ModelSpace.AddHatch(PatternType, patternName, bAssociativity)
  151. hatchObj2.AppendOuterLoop (outerLoop)
  152. hatchObj2.Layer = "red"
  153. hatchObj2.Evaluate
  154. plineObj.Delete  ' red hatch polyline
  155. points(0) = pntLL(0)
  156.     points(1) = pntLL(1)
  157.     points(2) = pntUL(0)
  158.     points(3) = pntUL(1)
  159.     points(4) = pntURBlue(0)
  160.     points(5) = pntURBlue(1)
  161.     points(6) = pntLRBlue(0)
  162.     points(7) = pntLRBlue(1)
  163.     points(8) = pntLL(0)
  164.     points(9) = pntLL(1)
  165. Set plineObj = ThisDrawing.ModelSpace.AddLightWeightPolyline(points)
  166. plineObj.Closed = False
  167. Set plineObjStar = ThisDrawing.ModelSpace.AddLightWeightPolyline(pointsStar)
  168. Dim innerLoop As Variant
  169. Dim innerLoopArray(0) As Object
  170. Set innerLoopArray(0) = plineObjStar
  171. innerLoop = innerLoopArray
  172. Set outerLoopArray(0) = plineObj
  173. outerLoop = outerLoopArray
  174. Set hatchObj3 = ThisDrawing.ModelSpace.AddHatch(PatternType, patternName, bAssociativity)
  175. hatchObj3.AppendOuterLoop (outerLoop)
  176. hatchObj3.AppendInnerLoop (innerLoop)
  177. hatchObj3.Layer = "blue"
  178. hatchObj3.Evaluate
  179. plineObj.Delete  ' red hatch polyline
  180. Set hatchobj4 = ThisDrawing.ModelSpace.AddHatch(PatternType, patternName, bAssociativity)
  181. hatchobj4.AppendOuterLoop (innerLoop)
  182. hatchobj4.Layer = "white"
  183. hatchobj4.Evaluate
  184. plineObjStar.Delete
  185. ThisDrawing.Regen True
  186. End Sub
  187. Private Function rtod(r As Double)
  188. rtod = (r * 180) / 3.14159265358979
  189. End Function
  190. Private Function dtor(d As Double)
  191. dtor = (d * 3.14159265358979) / 180
  192. End Function

本帖以下内容被隐藏保护;需要你回复后,才能看到!

游客,如果您要查看本帖隐藏内容请回复
回复

使用道具 举报

12

主题

175

帖子

77

银币

初露锋芒

Rank: 3Rank: 3Rank: 3

铜币
149
发表于 2017-11-16 06:22:09 | 显示全部楼层
您必须:
1)插入一个新的块对象
2)“添加”所有图形元素(图案填充、LwPoly)到此新创建的块,而不是图形模型空间
3)在图形模型空间中插入新块的块引用
以使代码的更改最小,如以下注释所述:
  1. Option Explicit
  2. Public Sub DrawTexasFlagOp()
  3.       
  4.     Dim PT1 As Variant
  5.     Dim PT2 As Variant
  6.    
  7.    
  8.     Dim pntLL(0 To 2) As Double
  9.     Dim pntLR(0 To 2) As Double
  10.     Dim pntUL(0 To 2) As Double
  11.     Dim pntUR(0 To 2) As Double
  12.     Dim pntLRBlue(0 To 2) As Double
  13.     Dim pntURBlue(0 To 2) As Double
  14.     Dim vertDist As Double
  15.     Dim horzDist As Double
  16.     Dim pntRW_Left(0 To 2) As Double
  17.     Dim pntRW_Right(0 To 2) As Double
  18.     Dim circleDiameter As Double
  19.     Dim cntPnt(0 To 2) As Double
  20.     Dim cir As AcadCircle
  21.     Dim starTopPoint(0 To 2) As Double
  22.     ' star leg length @ unit circle of 1 = .7265
  23.     ' starlegLength is variable
  24.     Dim starLegLen As Double
  25.     Dim starLegStart As Variant
  26.     Dim starLegEnd As Variant
  27.    
  28.    
  29.     PT1 = ThisDrawing.Utility.GetPoint(, "Pick lower left corner of Flag")
  30.     vertDist = ThisDrawing.Utility.GetDistance(PT1, vbCr & "Pick distance for vertical")
  31.     horzDist = (vertDist / 2) * 3
  32.     pntLL(0) = PT1(0) 'X value
  33.     pntLL(1) = PT1(1) 'Y value
  34.    
  35.    
  36.     pntUL(0) = PT1(0)
  37.     pntUL(1) = PT1(1) + vertDist
  38.    
  39.    
  40.     pntLR(0) = PT1(0) + horzDist
  41.     pntLR(1) = PT1(1)
  42.    
  43.    
  44.     pntUR(0) = PT1(0) + horzDist
  45.     pntUR(1) = PT1(1) + vertDist
  46.    
  47.    
  48.     pntLRBlue(0) = pntLL(0) + (horzDist / 3)
  49.     pntLRBlue(1) = pntLL(1)
  50.    
  51.    
  52.     pntURBlue(0) = pntLL(0) + (horzDist / 3)
  53.     pntURBlue(1) = pntLL(1) + vertDist
  54.    
  55.    
  56.     pntRW_Left(0) = pntLRBlue(0)
  57.     pntRW_Left(1) = pntLRBlue(1) + (vertDist / 2)
  58.     pntRW_Right(0) = pntLR(0)
  59.     pntRW_Right(1) = pntRW_Left(1)
  60.    
  61.    
  62.     circleDiameter = (horzDist / 3) * 0.75
  63.    
  64.    
  65.     cntPnt(0) = pntLL(0) + horzDist / 6
  66.     cntPnt(1) = pntLL(1) + vertDist / 2
  67.    
  68.    
  69.     starTopPoint(0) = cntPnt(0)
  70.     starTopPoint(1) = cntPnt(1) + (circleDiameter / 2)
  71.     starLegLen = 0.7265 * (circleDiameter / 2)
  72.    
  73.    
  74.     Dim plineObjStar As AcadLWPolyline
  75.     Dim pointsStar(0 To 21) As Double
  76.    
  77.    
  78.     starLegStart = starTopPoint
  79.     starLegEnd = ThisDrawing.Utility.PolarPoint(starLegStart, dtor(288), starLegLen)
  80.    
  81.    
  82.     pointsStar(0) = starTopPoint(0)
  83.     pointsStar(1) = starTopPoint(1)
  84.     pointsStar(2) = starLegEnd(0)
  85.     pointsStar(3) = starLegEnd(1)
  86.    
  87.    
  88.     starLegStart = starLegEnd
  89.    
  90.    
  91.     starLegEnd = ThisDrawing.Utility.PolarPoint(starLegStart, dtor(0), starLegLen)
  92.     pointsStar(4) = starLegEnd(0)
  93.     pointsStar(5) = starLegEnd(1)
  94.    
  95.    
  96.     starLegStart = starLegEnd
  97.     starLegEnd = ThisDrawing.Utility.PolarPoint(starLegStart, dtor(216), starLegLen)
  98.     pointsStar(6) = starLegEnd(0)
  99.     pointsStar(7) = starLegEnd(1)
  100.    
  101.    
  102.     starLegStart = starLegEnd
  103.     starLegEnd = ThisDrawing.Utility.PolarPoint(starLegStart, dtor(288), starLegLen)
  104.     pointsStar(8) = starLegEnd(0)
  105.     pointsStar(9) = starLegEnd(1)
  106.    
  107.    
  108.     starLegStart = starLegEnd
  109.     starLegEnd = ThisDrawing.Utility.PolarPoint(starLegStart, dtor(144), starLegLen)
  110.     pointsStar(10) = starLegEnd(0)
  111.     pointsStar(11) = starLegEnd(1)
  112.    
  113.    
  114.     starLegStart = starLegEnd
  115.     starLegEnd = ThisDrawing.Utility.PolarPoint(starLegStart, dtor(216), starLegLen)
  116.     pointsStar(12) = starLegEnd(0)
  117.     pointsStar(13) = starLegEnd(1)
  118.    
  119.    
  120.     starLegStart = starLegEnd
  121.     starLegEnd = ThisDrawing.Utility.PolarPoint(starLegStart, dtor(72), starLegLen)
  122.     pointsStar(14) = starLegEnd(0)
  123.     pointsStar(15) = starLegEnd(1)
  124.    
  125.    
  126.     starLegStart = starLegEnd
  127.     starLegEnd = ThisDrawing.Utility.PolarPoint(starLegStart, dtor(144), starLegLen)
  128.     pointsStar(16) = starLegEnd(0)
  129.     pointsStar(17) = starLegEnd(1)
  130.    
  131.    
  132.     starLegStart = starLegEnd
  133.     starLegEnd = ThisDrawing.Utility.PolarPoint(starLegStart, dtor(0), starLegLen)
  134.     pointsStar(18) = starLegEnd(0)
  135.     pointsStar(19) = starLegEnd(1)
  136.     pointsStar(20) = starTopPoint(0)
  137.     pointsStar(21) = starTopPoint(1)
  138.    
  139.    
  140.     Dim mylayer As AcadLayer
  141.     Set mylayer = ThisDrawing.Layers.Add("RED")
  142.     mylayer.color = acRed
  143.     Set mylayer = ThisDrawing.Layers.Add("WHITE")
  144.     mylayer.color = acWhite
  145.     Set mylayer = ThisDrawing.Layers.Add("BLUE")
  146.     mylayer.color = acBlue
  147.     Set mylayer = ThisDrawing.Layers.Item("RED")
  148.    
  149.    
  150.     ThisDrawing.ActiveLayer = ThisDrawing.Layers.Item("0")
  151.    
  152.    
  153.     Dim hatchObj As AcadHatch
  154.     Dim hatchObj2 As AcadHatch
  155.     Dim hatchObj3 As AcadHatch ' blue
  156.     Dim hatchobj4 As AcadHatch
  157.     Dim patternName As String
  158.     Dim PatternType As Long
  159.     Dim bAssociativity As Boolean
  160.     '------------------------------------------------------------
  161.     ' Define the block
  162.     Dim flagBlock As AcadBlock
  163.     Set flagBlock = ThisDrawing.Blocks.Add(PT1, "FlagBlock")
  164.     '------------------------------------------------------------
  165.    
  166.     With flagBlock '<--| reference the new block for all subsequent "Add" methods
  167.    
  168.         ' Define the hatch
  169.         patternName = "SOLID"
  170.         PatternType = 0
  171.         bAssociativity = True
  172.         Set hatchObj = .AddHatch(PatternType, patternName, bAssociativity) '<--| .AddHatch will add a hatch to the referenced block, instead of to the drawing modelspace
  173.         
  174.         
  175.         Dim plineObj As AcadLWPolyline
  176.         Dim points(0 To 9) As Double
  177.         points(0) = pntRW_Left(0)
  178.         points(1) = pntRW_Left(1)
  179.         points(2) = pntRW_Right(0)
  180.         points(3) = pntRW_Right(1)
  181.         points(4) = pntUR(0)
  182.         points(5) = pntUR(1)
  183.         points(6) = pntURBlue(0)
  184.         points(7) = pntURBlue(1)
  185.         points(8) = pntRW_Left(0)
  186.         points(9) = pntRW_Left(1)
  187.         Set plineObj = .AddLightWeightPolyline(points) '<--| .AddLightWeightPolyline will add a LWPoly to the referenced block, instead of to the drawing modelspace
  188.         plineObj.Closed = False
  189.         
  190.         
  191.         Dim outerLoop As Variant
  192.         Dim outerLoopArray(0) As Object
  193.         Set outerLoopArray(0) = plineObj
  194.         outerLoop = outerLoopArray
  195.         hatchObj.AppendOuterLoop (outerLoop)
  196.         
  197.         
  198.         hatchObj.Layer = "WHITE"
  199.         hatchObj.Evaluate
  200.         plineObj.Delete  ' white hatch polyline
  201.         ThisDrawing.Regen True
  202.         'create red hatch pline
  203.         points(0) = pntRW_Left(0)
  204.         points(1) = pntRW_Left(1)
  205.         points(2) = pntRW_Right(0)
  206.         points(3) = pntRW_Right(1)
  207.         points(4) = pntLR(0)
  208.         points(5) = pntLR(1)
  209.         points(6) = pntLRBlue(0)
  210.         points(7) = pntLRBlue(1)
  211.         points(8) = pntRW_Left(0)
  212.         points(9) = pntRW_Left(1)
  213.         Set plineObj = .AddLightWeightPolyline(points) '<--| see above comments
  214.         plineObj.Closed = False
  215.         Set outerLoopArray(0) = plineObj
  216.         outerLoop = outerLoopArray
  217.         
  218.         
  219.         Set hatchObj2 = .AddHatch(PatternType, patternName, bAssociativity) '<--| see above comments
  220.         hatchObj2.AppendOuterLoop (outerLoop)
  221.         
  222.         
  223.         hatchObj2.Layer = "red"
  224.         hatchObj2.Evaluate
  225.         plineObj.Delete  ' red hatch polyline
  226.         
  227.         
  228.         points(0) = pntLL(0)
  229.         points(1) = pntLL(1)
  230.         points(2) = pntUL(0)
  231.         points(3) = pntUL(1)
  232.         points(4) = pntURBlue(0)
  233.         points(5) = pntURBlue(1)
  234.         points(6) = pntLRBlue(0)
  235.         points(7) = pntLRBlue(1)
  236.         points(8) = pntLL(0)
  237.         points(9) = pntLL(1)
  238.         Set plineObj = .AddLightWeightPolyline(points) '<--| see above comments
  239.         plineObj.Closed = False
  240.         
  241.         
  242.         Set plineObjStar = .AddLightWeightPolyline(pointsStar) '<--| see above comments
  243.         Dim innerLoop As Variant
  244.         Dim innerLoopArray(0) As Object
  245.         Set innerLoopArray(0) = plineObjStar
  246.         innerLoop = innerLoopArray
  247.         
  248.         
  249.         Set outerLoopArray(0) = plineObj
  250.         outerLoop = outerLoopArray
  251.         Set hatchObj3 = .AddHatch(PatternType, patternName, bAssociativity) '<--| see above comments
  252.         hatchObj3.AppendOuterLoop (outerLoop)
  253.         hatchObj3.AppendInnerLoop (innerLoop)
  254.         hatchObj3.Layer = "blue"
  255.         hatchObj3.Evaluate
  256.         plineObj.Delete  ' red hatch polyline
  257.         
  258.         
  259.         Set hatchobj4 = .AddHatch(PatternType, patternName, bAssociativity) '<--| see above comments
  260.         hatchobj4.AppendOuterLoop (innerLoop)
  261.         hatchobj4.Layer = "white"
  262.         hatchobj4.Evaluate
  263.         plineObjStar.Delete
  264.     End With
  265.    
  266.     '------------------------------------------------------------
  267.     ' Insert the block
  268.     Dim blockRefObj As AcadBlockReference
  269.     Set blockRefObj = ThisDrawing.ModelSpace.InsertBlock(PT1, "FlagBlock", 1#, 1#, 1#, 0)
  270.     '------------------------------------------------------------
  271.     ThisDrawing.Regen True
  272.     ZoomAll
  273. End Sub
  274. Private Function rtod(r As Double)
  275.     rtod = (r * 180) / 3.14159265358979
  276. End Function
  277. Private Function dtor(d As Double)
  278.     dtor = (d * 3.14159265358979) / 180
  279. End Function

回复

使用道具 举报

12

主题

175

帖子

77

银币

初露锋芒

Rank: 3Rank: 3Rank: 3

铜币
149
发表于 2017-11-16 08:06:21 | 显示全部楼层
谢了。我想不出那个。我编程AutoCAD已经很久了
回复

使用道具 举报

12

主题

175

帖子

77

银币

初露锋芒

Rank: 3Rank: 3Rank: 3

铜币
149
发表于 2017-11-16 09:11:14 | 显示全部楼层
不客气
回复

使用道具 举报

发表回复

您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

  • 微信公众平台

  • 扫描访问手机版

  • 点击图片下载手机App

QQ|关于我们|小黑屋|乐筑天下 繁体中文

GMT+8, 2025-6-8 05:25 , Processed in 0.507005 second(s), 60 queries .

© 2020-2025 乐筑天下

联系客服 关注微信 帮助中心 下载APP 返回顶部 返回列表