选择相似区域多段线

ziorudy · 发表于 2022-7-5 17:48:36

你好，我是来寻求帮助的。
这是我的问题。我有很多poliline（复杂的custum拼花地板）。我必须选择所有具有相同区域的相同poliline（因此具有相同的形状）！有没有办法用列表例程解决我的问题？有人能帮我做吗？

非常感谢你！

pBe · 发表于 2022-7-5 17:53:04

欢迎来到CADTutor Ziorudy

尺寸相同？

MSasu · 发表于 2022-7-5 17:58:23

请检查内置命令QSELECT是否允许根据面积选择多段线图元。

pBe · 发表于 2022-7-5 18:02:49

这就是我要建议的MSasu，但请求是不明确的，“因此具有相同的形状”，因此我的Q。

MSasu · 发表于 2022-7-5 18:08:03

当然，一般来说，相同的面积并不意味着物品也有相同的形状。然而，在特定图纸中，它可以作为标准。
QSELECT也不会适应区域中的小变化。线程标题中的“相似区域”一词可能会让你想到这一点。

ziorudy · 发表于 2022-7-5 18:10:32

有些东西不起作用！

我选择我的所有多边形，qselect，choose area，等于：我单件的esact面积（123456789）。那么什么都不会发生！：x： x

Lee Mac · 发表于 2022-7-5 18:15:12

试试这个快速编写的程序：

copy


[color=GREEN];; Select Similar Area  -  Lee Mac[/color]
[color=GREEN];; Prompts the user to select a source polyline and[/color]
[color=GREEN];; selects all polylines in the active layout with a similar area.[/color]
([color=BLUE]defun[/color] c:ssarea ( [color=BLUE]/[/color] ent inc sel src )    
   ([color=BLUE]if[/color]
       ([color=BLUE]and[/color]
           ([color=BLUE]setq[/color] src
               (LM:SelectIf [color=MAROON]"\nSelect Source Polyline: "[/color]
                  '([color=BLUE]lambda[/color] ( x ) ([color=BLUE]wcmatch[/color] ([color=BLUE]cdr[/color] ([color=BLUE]assoc[/color] 0 ([color=BLUE]entget[/color] x))) [color=MAROON]"*POLYLINE"[/color]))
               )
           )
           ([color=BLUE]setq[/color] sel
               ([color=BLUE]ssget[/color] [color=MAROON]"_X"[/color]
                   ([color=BLUE]list[/color] '(0 . [color=MAROON]"*POLYLINE"[/color])
                       ([color=BLUE]if[/color] ([color=BLUE]=[/color] 1 ([color=BLUE]getvar[/color] 'cvport))
                           ([color=BLUE]cons[/color] 410 ([color=BLUE]getvar[/color] 'ctab))
                          '(410 . [color=MAROON]"Model"[/color])
                       )
                   )
               )
           )
           ([color=BLUE]setq[/color] src ([color=BLUE]vla-get-area[/color] ([color=BLUE]vlax-ename->vla-object[/color] src)))
       )
       ([color=BLUE]repeat[/color] ([color=BLUE]setq[/color] inc ([color=BLUE]sslength[/color] sel))
           ([color=BLUE]setq[/color] ent ([color=BLUE]ssname[/color] sel ([color=BLUE]setq[/color] inc ([color=BLUE]1-[/color] inc))))
           ([color=BLUE]if[/color] ([color=BLUE]not[/color] ([color=BLUE]equal[/color] src ([color=BLUE]vla-get-area[/color] ([color=BLUE]vlax-ename->vla-object[/color] ent)) 1e-3))
               ([color=BLUE]ssdel[/color] ent sel)
           )
       )
   )
   ([color=BLUE]sssetfirst[/color] [color=BLUE]nil[/color] sel)
   ([color=BLUE]princ[/color])
)
[color=GREEN];; Select If  -  Lee Mac[/color]
[color=GREEN];; Continuously prompts the user for a selection[/color]
[color=GREEN];; until a given predicate function is validated[/color]
([color=BLUE]defun[/color] LM:SelectIf ( msg prd [color=BLUE]/[/color] e )
   ([color=BLUE]setq[/color] prd ([color=BLUE]eval[/color] prd))
   ([color=BLUE]while[/color]
       ([color=BLUE]progn[/color] ([color=BLUE]setvar[/color] 'ERRNO 0) ([color=BLUE]setq[/color] e ([color=BLUE]car[/color] ([color=BLUE]entsel[/color] msg)))
           ([color=BLUE]cond[/color]
               (   ([color=BLUE]=[/color] 7 ([color=BLUE]getvar[/color] 'ERRNO))
                   ([color=BLUE]princ[/color] [color=MAROON]"\nMissed, try again."[/color])
               )
               (   ([color=BLUE]eq[/color] 'ENAME ([color=BLUE]type[/color] e))
                   ([color=BLUE]if[/color] ([color=BLUE]and[/color] prd ([color=BLUE]null[/color] (prd e)))
                       ([color=BLUE]princ[/color] [color=MAROON]"\nInvalid Object."[/color])
                   )
               )
           )
       )
   )
   e
)
([color=BLUE]vl-load-com[/color]) ([color=BLUE]princ[/color])