[编程交流] 使用存储特定点

;; Selection Set Bounding Box  -  Lee Mac
;; Returns a list of the lower-left and upper-right WCS coordinates of a
;; rectangular frame bounding all objects in a supplied selection set.
;; s - [sel] Selection set for which to return bounding box
(defun LM:ssboundingbox ( s / a b i m n o )
   (repeat (setq i (sslength s))
       (if
           (and
               (setq o (vlax-ename->vla-object (ssname s (setq i (1- i)))))
               (vlax-method-applicable-p o 'getboundingbox)
               (not (vl-catch-all-error-p (vl-catch-all-apply 'vla-getboundingbox (list o 'a 'b))))
           )
           (setq m (cons (vlax-safearray->list a) m)
                 n (cons (vlax-safearray->list b) n)
           )
       )
   )
   (if (and m n)
       (mapcar '(lambda ( a b ) (apply 'mapcar (cons a b))) '(min max) (list m n))
   )
)
(defun c:test ( / b s )
   (if
       (and
           (setq s (ssget))
           (setq b (LM:ssboundingbox s))
       )
       (entmake
           (append
              '(
                   (000 . "LWPOLYLINE")
                   (100 . "AcDbEntity")
                   (100 . "AcDbPolyline")
         ; MAKE THE POLYLINE ON DEFPOINTS
                   (090 . 4)
                   (070 . 1)
               )
               (mapcar '(lambda ( x ) (cons 10 (mapcar '(lambda ( y ) ((eval y) b)) x)))
                  '(
                       (caar   cadar)
                       (caadr  cadar)   ; THIS IS UNDER RIGHT, HOW TO STORE THIS POINT AS PAPER_ORIGIN?
                       (caadr cadadr)
                       (caar  cadadr)
                   )
               )
           )
       )
     )
     (COMMAND "MOVE" "ALL" ""
                
                       (caadr  cadar)   ; THIS IS UNDER RIGHT, STORED POINT FOR PAPER_ORIGIN
                                 
                        
       "0,0" "")
   (princ)
)
(vl-load-com)

;; Selection Set Bounding Box  -  Lee Mac
;; Returns a list of the lower-left and upper-right WCS coordinates of a
;; rectangular frame bounding all objects in a supplied selection set.
;; s - [sel] Selection set for which to return bounding box
(defun LM:ssboundingbox ( s / a b i m n o )
   (repeat (setq i (sslength s))
       (if
           (and
               (setq o (vlax-ename->vla-object (ssname s (setq i (1- i)))))
               (vlax-method-applicable-p o 'getboundingbox)
               (not (vl-catch-all-error-p (vl-catch-all-apply 'vla-getboundingbox (list o 'a 'b))))
           )
           (setq m (cons (vlax-safearray->list a) m)
                 n (cons (vlax-safearray->list b) n)
           )
       )
   )
   (if (and m n)
       (mapcar '(lambda ( a b ) (apply 'mapcar (cons a b))) '(min max) (list m n))
   )
)
(defun c:test ( / b s )
   (if
       (and
           (setq s (ssget))
           (setq b (LM:ssboundingbox s))
       )
       (command "_.move" s "" "_non" (list (caadr b) (cadar b)) "_non" '(0.0 0.0))
   )
   (princ)
)
(vl-load-com)

(ssget "X" )(67 . 1) ; only the paperspace stuff.. 

(defun c:test ( / box ctb sel )
   (setq ctb (getvar 'ctab))
   (foreach tab (layoutlist)
       (setvar 'ctab tab)
       (if (and (setq sel (ssget "_X" (list '(-4 . "<NOT") '(-4 . "<AND") '(0 . "VIEWPORT") '(69 . 1) '(-4 . "AND>") '(-4 . "NOT>") (cons 410 tab))))
                (setq box (LM:ssboundingbox sel))
           )
           (command "_.move" sel "" "_non" (list (caadr box) (cadar box)) "_non" '(0.0 0.0))
       )
   )
   (setvar 'ctab ctb)
   (princ)
)

(ssget "_X" (list '(69 . 1) (cons 410 tab)))

6