[编程交流] 在上实时发出两个命令

(command "._PLINE")
  (while (> (logand (getvar "CMDACTIVE") 1) 0)
    (command PAUSE)
  ) 

;| Tangent Leader for labeling
  BY: Tom Beauford
  BeaufordT@LeonCountyFL.gov
  Leon County Public Works Engineering Section
  Macro: ^P(or C:tld (load "Arrow.lsp"));tld
  Command line: (load "Arrow.lsp") tld
==============================================================================|;
(defun C:tld (/ *ERROR* st_txt rem ts pt1 pt2 pt3 pt4 arow addv)
(defun *ERROR* (s)                    ; If an error (such as CTRL-C) occurs
                                     ; while this command is active...
 (if (/= s "Function cancelled")
   (princ (strcat "\nError: " s))
 )
 (command "ucs" "Restore" "$temp$")  ; Restore saved coordinate system.
 (command "ucs" "Del" "$temp$")      ; Delete $temp$ coordinate system.
 (grtext -1 "")                      ; Clear status line.
 (setvar "osmode" rem)
 (princ)
)
(setq st_txt (strcat "Arrow size = Text Size = " (rtos(getvar "textsize")2 2)))
(grtext -1 st_txt)
(setvar "CMDECHO" 0)
(setq rem (getvar "osmode"))
(setvar 'osmode (boole 7 (getvar 'osmode) 16384))
(command "ucs" "Del" "$temp$")
(command "ucs" "Save" "$temp$")
(command "ucs" "World")
(setq
 ts  (getvar "textsize")
 pt1 (getpoint "Start at object to be labeled: ")
 pt3 (getpoint pt1 "\n\nTo: "))
(setq
 pt1 (list(car pt1)(cadr pt1))
 pt3 (list(car pt3)(cadr pt3))
 pt2
  (list
   (- (car pt1)(* (/ ts (distance pt1 pt3))
      (-(car pt1)(car pt3)))
   )
   (- (cadr pt1)(* (/ ts (distance pt1 pt3))
      (-(cadr pt1)(cadr pt3)))
   )
  )
)
(setq arow (list
             '(0 . "LWPOLYLINE")
             '(100 . "AcDbEntity")
             (cons 8 (getvar "clayer"))         ;current layer
             '(6 . "CONTINUOUS")                ;linetype
             '(100 . "AcDbPolyline")
             '(90 . 3)                          ;# of vertices
             '(39 . 0.0)
             (list 10(car pt1)(cadr pt1))       ;vertex
             '(40 . 0.0)                        ;starting width
             (cons 41 (/ ts 3))  ;ending width
             '(42 . 0.0)                        ;bulge (external of curve)
             (list 10(car pt2)(cadr pt2))       ;vertex
;              (cons 40 (/ ts 30)) ;starting width
             '(40 . 0.0) ;starting width
;              (cons 41 (/ ts 30)) ;ending width
             '(41 . 0.0) ;ending width
             '(42 . 0.0)                        ;bulge (external of curve)
             (list 10(car pt3)(cadr pt3))       ;vertex
;              (cons 40 (/ ts 30)) ;starting width
             '(40 . 0.0) ;starting width
;              (cons 41 (/ ts 30)) ;ending width
             '(41 . 0.0) ;ending width
             '(42 . 0.0)                        ;bulge (external of curve)
             '(210 0.0 0.0 1.0)                 ;extrusion direction
            )
)
(entmake arow)
(setq en (entlast))
(setq ed (entget en))
(setq pt4 nil)
(setq pt4 (getpoint pt3))
(while pt4
 (setq ed (reverse(cdr(reverse ed))))
 (setq ed (subst(cons 90(+(cdr(assoc 90 ed))1))(assoc 90 ed)ed))  ;# of vertices
 (setq addv (list
              (list 10(car pt4)(cadr pt4))       ;vertex
              '(40 . 0.0) ;starting width
;               (cons 40 (/ ts 30)) ;starting width
              '(41 . 0.0) ;ending width
;               (cons 41 (/ ts 30)) ;ending width
              '(42 . 0.0)                        ;bulge (external of curve)
              '(210 0.0 0.0 1.0)                 ;extrusion direction
             ); end list
 ); end setq
 (setq ed(append ed addv))
 (entmod ed)
 (setq pt3 pt4)
 (setq pt4 nil)
 (setq pt4 (getpoint pt3))
 (princ)
); end while
(setvar "osmode" rem)
(command "ucs" "Restore" "$temp$")
(command "ucs" "Del" "$temp$")
(grtext -1 "") ;CLEAR STATUS LINE
(princ)
)