按shor对选定实体排序

vanowm · 发表于 2022-7-5 18:08:54

你好
有人能提出一种方法，按一个图元的终点坐标和下一个图元的起点坐标之间的最短距离对选定图元的列表进行排序吗？

下面是一个示例：

登录/注册后可看大图

黄点代表实体的开始，数字是它们应该结束的顺序。
#1行最接近0,0；其终点坐标最接近拱门#2，然后是多段线#3，依此类推。

非常感谢。

附笔。
我试图实现的是优化绘图仪的绘图方式。它的驱动程序无法优化其绘制方式，这似乎遵循了在图形中创建实体的顺序。现在，我必须手动复制每个实体一个一个地在正确的顺序，我希望它的方式来绘图。。。

Lee Mac · 发表于 2022-7-5 18:48:34

该问题本质上是旅行商问题（即沿着最短路径访问所有节点）。以下是实现最近邻贪婪算法的解决方案-请注意，这种方法不会产生最佳结果：

copy

(defun sortentlist ( lst / foo rtn )
   (setq foo
       (lambda ( x l / a d r )
           (setq d (distance (caddr x) (cadar l))
                 r (car l)
           )
           (foreach y (cdr l)
               (if (< (setq a (distance (cadr y) (caddr x))) d)
                   (setq d a r y)
               )
           )
           r
       )
   )
   (setq lst (mapcar '(lambda ( x ) (list x (vlax-curve-getstartpoint x) (vlax-curve-getendpoint x))) lst)
         rtn (list (car lst))
         lst (cdr lst)
   )
   (while lst
       (setq rtn (cons (foo (car rtn) lst) rtn)
             lst (vl-remove (car rtn) lst)
       )
   )
   (reverse (mapcar 'car rtn))
)

该算法也可以使用排序来实现，但效率较低：

copy

(defun sortentlist ( lst / rtn )
   (setq lst (mapcar '(lambda ( x ) (list x (vlax-curve-getstartpoint x) (vlax-curve-getendpoint x))) lst)
         rtn (list (car lst))
         lst (cdr lst)
   )
   (while lst
       (setq lst (vl-sort lst '(lambda ( a b ) (< (distance (caddar rtn) (cadr a)) (distance (caddar rtn) (cadr b)))))
             rtn (cons (car lst) rtn)
             lst (vl-remove (car rtn) lst)
       )
   )
   (reverse (mapcar 'car rtn))
)

BIGAL · 发表于 2022-7-5 19:35:19

李这不是另一个帖子的问题，如何使激光切割机做下一个最接近的项目，节省头部移动时间。

[编程交流] 按shor对选定实体排序

发表回复

精选推荐