[编程交流] 拆分列表

; Iterative Version
;; Group by Number  -  Lee Mac
;; Groups a list 'l' into a list of lists, each of length 'n'
(defun LM:groupbynum ( l n / a b )
   (while l
       (repeat n
           (setq a (cons (car l) a)
                 l (cdr l)
           )
       )
       (setq b (cons (reverse a) b)
             a nil
       )
   )
   (reverse b)
)

(defun foo ( l n )
   (if l (bar (cons nil l) n n))
)
(defun bar ( l m n )
   (if (and (cdr l) (< 0 n))
       (bar (cons (cons (cadr l) (car l)) (cddr l)) m (1- n))
       (cons (reverse (car l)) (foo (cdr l) m))
   )
)

_$ (foo '(1 2 3 4 5 6) 2)
((1 2) (3 4) (5 6))
_$ (foo '(1 2 3 4 5 6) 3)
((1 2 3) (4 5 6))
_$ (foo '(1 2 3 4 5 6) 4)
((1 2 3 4) (5 6))

(defun gbn ( l n / a b m )
   (while l
       (setq m n)
       (while (and l (< 0 m))
           (setq a (cons (car l) a)
                 l (cdr l)
                 m (1- m)
           )
       )
       (setq b (cons (reverse a) b)
             a nil
       )
   )
   (reverse b)
)

_$ (gbn '("A" "B" "C" "D" "E" "F") 5)
(("A" "B" "C" "D" "E") ("F"))

(defun _split:list (l r / _l _lst)
 ;; Tharwat 17.09.2015    ;;
 (mapcar '(lambda (x)
            (setq _l (cons x _l))
            (if (= (length _l) r)
              (setq _lst (cons (reverse _l) _lst)
                    _l   nil
              )
            )
          )
         l
 )
 (if _l
   (setq _lst (cons (reverse _l) _lst))
 )
 (reverse _lst)
)

(defun foo ( l n / a b i )
   (setq i 0)
   (foreach x l
       (setq a (cons x a)
             i (1+ i)
       )
       (if (zerop (rem i n))
           (setq b (cons (reverse a) b)
                 a nil
           )
       )
   )
   (reverse (if a (cons (reverse a) b) b))
)

(defun _split:list (l r / _l _lst)
 (foreach x l
   (setq _l (cons x _l))
   (if (= (length _l) r)
     (setq _lst (cons (reverse _l) _lst)
           _l   nil
     )
   )
 )
 (reverse (if _l
            (setq _lst (cons (reverse _l) _lst))
            _lst
          )
 )
)