grread公司

samifox · 发表于 2022-7-5 19:39:55

你好

我遵循这个代码，它的操作方式与fens选择模式相同，

除了两样东西，我都有，

（grread 5），5代表什么？（不懂文件）
什么使PT为零？（当它终止程序主循环时）


(defun VECTORS (/ PT PTLIST)
 ; Sequential choice of points
 ; by ElpanovEvgeniy
 ; (2005-10-19 17:59:01)
 ; (VECTORS)
 (setq PTLIST (list
                (setq PT (getpoint "\n Specify the first point  "))
              ) ;_  list
 ) ;_  setq
 (princ "\n Specify the following point  ")
 (princ)
 (while
   (setq PT
          (progn (while
                   (and (setq PT (grread 5))
                        (= (car PT) 5)
                   ) ;_  and
                    (redraw)
                    (mapcar
                      (function
                        (lambda (x1 x2)
                          (grdraw x1 x2 6 5)
                        ) ;_  lambda
                      ) ;_  function
                      (cons (cadr PT) PTLIST)
                      PTLIST
                    ) ;_  mapcar
                 ) ;_  while
                 (if (listp (cadr PT))
                   (cadr PT)
                 ) ;_  if
          ) ;_  progn
   ) ;_  setq
    (setq PTLIST (cons PT PTLIST))
 ) ;_  while
) ;_  defun

谢谢

Lee Mac · 发表于 2022-7-5 19:52:15

整数5对应于grread的allkeys参数，是位代码1（返回“拖动模式”坐标）和4（使用“curtype”参数中传递的值来控制光标显示）的组合。

grread函数通常不会返回nil；while循环通常在（car PT）不等于5时终止，即当用户输入不是鼠标移动时（例如2=键盘输入，3=左键单击等）。