如何获取属性信息

JJtre · 发表于 2022-7-5 20:23:07

好的，我再打一次，但我有一个问题，这意味着什么
“_+：E:S”？直到我开始这项任务，我才看到这一点。谢谢李的信心提升。

Lee Mac · 发表于 2022-7-5 20:25:35

这是ssget模式字符串的组合，其中有两个未记录：


_  = allow for language compatibility
+. = force point selection (similar to PICKAUTO=0)
:E = select everything in the cursor aperture
:S = forces single entity selection

关于您的任务，您是否希望为选择中的所有块检索特定标记的值？还是所有标记的所有值？这两种方法都可以实现，您只需要考虑如何构建列表输出。

李

Lee Mac · 发表于 2022-7-5 20:31:17

在检索多个值的示例中，使用了与我前面的链接中演示的相同的方法。

选择后，将构造一个列表并打印到命令行，该列表采用以下形式：

copy

((<tag1> <value1> ... <valueN>) (<tag2> <value1> ... <valueN>) ... (<tagN> <value1> ... <valueN>))

copy


(defun c:test ( / _assoc++ ss )
 ;; Example by Lee Mac 2010 www.lee-mac.com
 (defun _assoc++ ( key value lst )
   (
     (lambda ( pair )
       (if pair
         (subst (cons key (cons value (cdr pair))) pair lst)
         (cons  (list key value) lst)
       )
     )
     (assoc key lst)
   )
 )
 (if (setq ss (ssget '((0 . "INSERT") (66 . 1))))
   (
     (lambda ( i / e el l )
       (while (setq e (ssname ss (setq i (1+ i))))
         (while
           (not
             (eq "SEQEND"
               (cdr
                 (assoc 0
                   (setq el
                     (entget
                       (setq e (entnext e))
                     )
                   )
                 )
               )
             )
           )
           (setq l (_assoc++ (cdr (assoc 2 el)) (cdr (assoc 1 el)) l))
         )
       )
       (print l)
     )
     -1
   )
 )
 (princ)
)