文本到excel

Wesley_Amsterda · 发表于 2022-7-5 22:15:22

大家好，

我有一个以z坐标为文本的图形。
我想导出所有文本对象及其x坐标和y坐标，并将文本内容用于z坐标。

找到附件中的示例。

我找不到任何关于网络搜索的东西。
Text2excel。图纸

MSasu · 发表于 2022-7-5 22:29:39

请检查内置的数据提取命令。仅将其应用于文本实体，并保留位置X、位置Y和值属性。

Tharwat · 发表于 2022-7-5 22:35:05

试试这个。


(defun c:Test (/ ss f o)
 ;;    Tharwat 05.11.2014             ;;
 ;;    Export Texts' values to Excel    ;;
 (princ "\n << Select Texts to export to Excel : >>")
 (if (and (setq ss (ssget '((0 . "TEXT")
                           )
                   )
          )
          (setq f (getfiled "Save as :" (getvar 'DWGPREFIX) "csv" 1))
     )
   (progn
     (setq o (open f "w"))
     (write-line
       "X-coordinate of text;Y-coordinate of text;Z-coordinate of text value"
       o
     )
     ((lambda (i / sn p e)
        (while (setq sn (ssname ss (setq i (1+ i))))
          (write-line
            (strcat
              (rtos
                (car (setq p (cdr (assoc 10 (setq e (entget sn))))))
                2
              )
              ";"
              (rtos (cadr p) 2)
              ";"
              (cdr (assoc 1 e))
            )
            o
          )
        )
      )
       -1
     )
     (close o)
   )
 )
 (princ)
)