[编程交流] 有什么常规安排吗

(defun C:FIXTEXT ( / *error* acDoc round ss d)
 
 (defun round (n) (* d (fix (+ 0.5 (/ (abs n) d))) (if (minusp n) -1 1)))
 
 (vla-startundomark (setq acDoc (vla-get-activedocument (vlax-get-acad-object))))
 
 (defun *error* (msg)
   (and
     msg
     (not (wcmatch (strcase msg) "*EXIT*,*QUIT*,*CANCEL*"))
     (princ (strcat "\nError: " msg))
     )
   (vla-endundomark acDoc)
   (princ)
   )
 
 (if
   (and
     (setq ss (ssget ":L" '((0 . "TEXT"))))
     (progn
       (initget 6)
       (setq d (getdist "\nSnap value: "))
     )
   )
   (repeat (setq i (sslength ss))
     (entmod
       (mapcar
         (function
           (lambda (x)
             (if
               (<= 10 (car x) 11)
               (cons (car x) (mapcar 'round (cdr x)))
               x
             )
           )
         )
         (entget (ssname ss (setq i (1- i))))
       )
     )
   )
 )
 (vla-endundomark acDoc)
 (princ)
)

(defun c:round ( / e i k l m s ) ;LEE MAC
   (setq l
      '(
           ("CIRCLE"     10 40)
           ("LINE"       10 11)
           ("LWPOLYLINE" 10)
           ("INSERT"     10)
           ("POINT"      10)
       )
   )            
   (if (null *tol*)
       (setq *tol* 5.0)
   )
   (initget 6)
   (if (setq m (getreal (strcat "\nSpecify rounding tolerance <" (rtos *tol*) ">: ")))
       (setq *tol* m)
       (setq m *tol*)
   )
   (if (setq s (ssget "_:L" '((0 . "CIRCLE,LINE,LWPOLYLINE,INSERT,POINT"))))
       (repeat (setq i (sslength s))
           (if (setq e (entget (ssname s (setq i (1- i))))
                     k (cdr (assoc (cdr (assoc 0 e)) l))
               )
               (entmod (rounddxf k m e))
           )
       )
   )
   (princ)
)
(defun rounddxf ( key mod lst / rtn )
   (foreach itm lst
       (if (member (car itm) key)
           (setq rtn (cons (cons (car itm) (roundvalue (cdr itm) mod)) rtn))
           (setq rtn (cons itm rtn))
       )
   )
   (reverse rtn)
)
(defun roundvalue ( val mod )
   (if (listp val)
       (mapcar '(lambda ( x ) (round x mod)) val)
       (round val mod)
   )
)
;; Doug Broad
(defun round ( value to )
   (setq to (abs to))
   (* to (fix (/ ((if (minusp value) - +) value (* to 0.5)) to)))
)
(princ)

(defun c:round ( / e i k l m s ) ; LEE MAC
   (setq l
      '(
           ("CIRCLE"     10 40)
           ("LINE"       10 11)
           ("LWPOLYLINE" 10)
           ("INSERT"     10)
           ("POINT"      10)
[color=red]            ("MTEXT"      10)
           ("TEXT"       10 11)[/color]
       )
   )
   ...
)