图层选择

monk · 发表于 2022-7-5 22:43:39

是否有更清洁/更快的方法来实现这一点；

(defun JHSETCOL1 ( /  )
(if (not JHCOL1)
                (setq JHCOL1 "7")
                )
(command "-layer" "C" JHCOL1 "*inv*" "")
(command "-layer" "C" JHCOL1 "*dim*" "")
(command "-layer" "C" JHCOL1 "*alias*" "")
        
 (princ)
 
)

本质上，我想使用通配符更改选定层的颜色。我有一个DCL框，您可以输入颜色“JHCOL1”

对使用通配符的lisp的层选择方面更感兴趣。。。

Lee Mac · 发表于 2022-7-5 22:59:51

您可以通过使用逗号分隔模式来匹配多个通配符模式，例如：

copy

(defun jhsetcol1 ( col )
   (if (null col) (setq col 7))
   (command "_.-layer" "_c" col "*inv*,*dim*,*alias*" "")
   (princ)
)

或者，使用Vanilla AutoLISP而不使用-LAYER命令：

copy

(defun jhsetcol2 ( col / def dxf enx lay )
   (if (null col) (setq col 7))
   (while (setq lay (tblnext "layer" (null lay)))
       (if (wcmatch (setq lay (cdr (assoc 2 lay))) "*inv*,*dim*,*alias*")
           (progn
               (setq enx (entget (tblobjname "layer" lay))
                     dxf (assoc 62 enx)
               )
               (entmod (subst (cons 62 (if (minusp (cdr dxf)) (- col) col)) dxf enx))
           )
       )
   )
   (princ)
)