将二维文字转换为三维点

CSTAM · 发表于 2022-7-5 22:51:01

有谁知道如何将二维文本转换为三维点，一次完成整个图形？

MSasu · 发表于 2022-7-5 23:03:52

假设文字实体具有所需三维点的坐标-这可以通过AutoLISP例程完成。
应该张贴一个带有坐标格式的示例。

也可以要求版主在AutoLISP、VBA、CUI和自定义部分中移动您的端口。

当做

BearDyugin · 发表于 2022-7-5 23:12:20

(defun C:Convert_Text_to_Point (/ ss Z_value temp koord)
 (if (setq ss (ssget "_:L" '((0 . "Text"))))
   (progn
     (initget "Koord Value")
     (setq
Z_value        (getkword "\nTake Z from [Koord/Value]? <Value>:")
Z_value        (if Z_value
          Z_value
          "Value"
        )
ss        (vl-remove-if-not
          '(lambda (x) (= (type x) 'ENAME))
          (mapcar 'cadr (ssnamex ss))
        )
     )
     (foreach item ss
(setq temp  (entget item)
      koord (cdr (assoc 10 temp))
      koord (if        (eq Z_value "Value")
              (list (car koord)
                    (cadr koord)
                    (atof (cdr (assoc 1 temp)))
              )
              koord
            )
)
(entdel item)
(entmakex
  (list
    '(0 . "POINT")
    (cons 10 koord)
  )
)
     )
   )
 )
)