[编程交流] 如何将区域馈送到vla addr

(defun c:try3 ()
  (setq doc   (vla-get-activedocument (vlax-get-acad-object))
        space (vlax-get-property doc (if (= 1 (getvar 'cvport))'paperspace 'modelspace))
        p1 '(0.5 0.0)
        p2 '(0.5 1.0)
        p3 '(1.9 1.0)
        p4 '(2.0 0.9)
        p5 '(2.0 0.1)
        p6 '(1.9 0.0)
        rotAxisPt (vlax-3d-point 0 0 0)
        rotAxisDir (vlax-3d-point 0 1 0)
        rotAngle 6.28
        sh1 (vlax-ename->vla-object
               (entmakex
                  (list
                     (cons 0 "LWPOLYLINE")
                     (cons 100 "AcDbEntity")
                     (cons 100 "AcDbPolyline")
                     (cons 90 6)
                     (cons 70 1)
                     (cons 10 p1)
                     (cons 10 p2)
                     (cons 10 p3)
                     (cons 10 p4)
                     (cons 10 p5)
                     (cons 10 p6)
                  )
               )
            )
        region1 (vlax-invoke space 'addregion (list sh1))
        solidObj (vla-AddRevolvedSolid Space (vlax-safearray-get-element (vlax-variant-value region1) 0) rotAxisPt rotAxisDir rotAngle)
  )
)

(defun c:try5 ( / doc ply reg sol spc )
   (setq doc (vla-get-activedocument (vlax-get-acad-object))
         spc (vlax-get-property doc (if (= 1 (getvar 'cvport)) 'paperspace 'modelspace))
         ply (vla-addlightweightpolyline spc
                 (vlax-make-variant
                     (vlax-safearray-fill
                         (vlax-make-safearray vlax-vbdouble '(0 . 11))
                        '(0.5 0.0 0.5 1.0 1.9 1.0 2.0 0.9 2.0 0.1 1.9 0.0)
                     )
                 )
             )
   )
   (vla-put-closed ply :vlax-true)
   (setq reg (vlax-safearray-get-element
                 (vlax-variant-value
                     (vla-addregion spc
                         (vlax-make-variant
                             (vlax-safearray-fill
                                 (vlax-make-safearray vlax-vbobject '(0 . 0))
                                 (list ply)
                             )
                         )
                     )
                 )
                 0
             )
         sol (vla-addrevolvedsolid spc reg
                 (vlax-3D-point 0 0)
                 (vlax-3D-point 0 1)
                 (+ pi pi)
             )
   )
   (vla-delete reg)
   (vla-delete ply)
   (princ)
)

3