[编程交流] 从lis中删除子列表

(defun Eliminate( triangList )
(foreach subList triangList
 (if (or (equal (car  subList) (cadr  subList) 0.1)
         (equal (car  subList) (caddr subList) 0.1)
         (equal (cadr subList) (caddr subList) 0.1))
  (setq triangList (vl-remove subList triangList))
 )
)
triangList
)

(defun Eliminate( triangList / )
(vl-remove nil (mapcar '(lambda (a)
                         (if (or (equal (car  a) (cadr  a) 0.1)
                                 (equal (car  a) (caddr a) 0.1)
                                 (equal (cadr a) (caddr a) 0.1))
                          nil
                          a
                         )
                        )
                       triangList)
)
)

(defun foo ( l )
   (cond
       (   (null l) nil)
       (   (bar (car l)) (foo (cdr l)))
       (   (cons (car l) (foo (cdr l))))
   )
)
(defun bar ( x )
   (cond
       (   (null x) nil)
       (   (vl-some '(lambda ( y ) (equal (car x) y 0.1)) (cdr x)))
       (   (bar (cdr x)))
   )
)

_$ (foo '(((3.0 2.0) (3.0 2.0) (4.0 5.0)) ((4.0 6.0) (8.0 9.0) (12.0 15.0))))
(((4.0 6.0) (8.0 9.0) (12.0 15.0)))

(defun foo ( l )
   (vl-remove-if
      '(lambda ( x )
           (while (and (cdr x) (not (vl-some '(lambda ( y ) (equal (car x) y 0.1)) (cdr x))))
               (setq x (cdr x))
           )
           (cdr x)
       )
       l
   )
)

_$ (foo '(((3.0 2.0) (4.0 5.0) (8.0 9.0) (3.0 2.0)) ((4.0 6.0) (8.0 9.0) (12.0 15.0))))
(((4.0 6.0) (8.0 9.0) (12.0 15.0)))