从模型空间t复制对象

Lee Mac · 发表于 2022-7-6 00:05:02

我很乐意帮忙，但现在没有太多时间来考虑这个问题——如果我有时间的话，可能在周末。

steven-g · 发表于 2022-7-6 00:08:25

你真的需要整整一分钟吗。

Lee Mac · 发表于 2022-7-6 00:11:46

.......

Lee Mac · 发表于 2022-7-6 00:14:47

我花了一些时间来研究这个问题，并快速编写了以下草稿，但是该程序目前仅限于在viewtwist为零的视口中使用：

copy


[color=GREEN];; Modelspace to Paperspace  -  Lee Mac[/color]
([color=BLUE]defun[/color] c:ms2ps ( [color=BLUE]/[/color] doc idx lst mat org sel )
   ([color=BLUE]cond[/color]
       (   ([color=BLUE]=[/color] 1 ([color=BLUE]getvar[/color] 'tilemode))
           ([color=BLUE]prompt[/color] [color=MAROON]"\nCommand only available in Paperspace."[/color])
       )
       (   ([color=BLUE]=[/color] 1 ([color=BLUE]getvar[/color] 'cvport))
           ([color=BLUE]prompt[/color] [color=MAROON]"\nPlease activate a viewport."[/color])
       )
       (   ([color=BLUE]setq[/color] sel ([color=BLUE]ssget[/color] '((410 . [color=MAROON]"Model"[/color]))))
           ([color=BLUE]repeat[/color] ([color=BLUE]setq[/color] idx ([color=BLUE]sslength[/color] sel))
               ([color=BLUE]setq[/color] lst ([color=BLUE]cons[/color] ([color=BLUE]vlax-ename->vla-object[/color] ([color=BLUE]ssname[/color] sel ([color=BLUE]setq[/color] idx ([color=BLUE]1-[/color] idx)))) lst))
           )
           ([color=BLUE]setq[/color] mat
               ([color=BLUE]vlax-tmatrix[/color]
                   ([color=BLUE]append[/color]
                       ([color=BLUE]mapcar[/color]
                          '([color=BLUE]lambda[/color] ( a b )
                               ([color=BLUE]append[/color] ([color=BLUE]mapcar[/color] '[color=BLUE]-[/color] ([color=BLUE]trans[/color] ([color=BLUE]trans[/color] a 0 2) 2 3) org) ([color=BLUE]list[/color] b))
                           )
                          '(
                               (1.0 0.0 0.0)
                               (0.0 1.0 0.0)
                               (0.0 0.0 1.0)
                           )
                           ([color=BLUE]setq[/color] org ([color=BLUE]trans[/color] ([color=BLUE]trans[/color] '(0.0 0.0 0.0) 0 2) 2 3))
                       )
                      '((0.0 0.0 0.0 1.0))
                   )
               )
           )
           ([color=BLUE]foreach[/color] obj
               ([color=BLUE]vlax-invoke[/color] ([color=BLUE]setq[/color] doc ([color=BLUE]vla-get-activedocument[/color] ([color=BLUE]vlax-get-acad-object[/color]))) 'copyobjects lst
                   ([color=BLUE]vla-get-block[/color]
                       ([color=BLUE]vla-item[/color]
                           ([color=BLUE]vla-get-layouts[/color] doc)
                           ([color=BLUE]getvar[/color] 'ctab)
                       )
                   )
               )
               ([color=BLUE]vla-transformby[/color] obj mat)
           )
       )
   )
   ([color=BLUE]princ[/color])
)
([color=BLUE]vl-load-com[/color]) ([color=BLUE]princ[/color])

nod684 · 发表于 2022-7-6 00:17:35

这是我们以前在办公室使用的。
命令包括：

C2P=复制到纸面空间&M2P=移动到纸面空间
C2M=复制到模型空间&M2M=移动到模型空间

然而，它有这个“买我”的东西。

将所有内容放在一个文件夹中，该文件夹应列在autocad的支持文件夹中
SP2SP。LSP
sp2sp。dcl
SP2SP。拉链

shailujp · 发表于 2022-7-6 00:20:39

谢谢李抽出时间做这件事。以下是我的观察结果：

1）可以让用户激活视口而不是终止命令吗？
2）它不会提取所选实体。目前它正在复制整个区块（这是一件必备品）
3）视口显示是否可以临时锁定？否则，如果用户在模型空间模式下放大，可能会弄乱图形。（安全功能）
4）选择完成后，是否可以自动返回到图纸空间，然后关闭命令。

我不确定哪一个不能做到，但我还是想提一提，这样你们可以更好地做出决定。

Nod684：我不能使用你发布的代码，因为里面有一些版权的东西。谢谢你的帮助。

shailujp · 发表于 2022-7-6 00:22:12

嗨，李，

我看到你在网站上添加了MS2P。是否有可能添加我在第16篇文章中列出的一些愿望/要求。

Bhull1985 · 发表于 2022-7-6 00:27:59

以下是如何锁定/解锁视口（vpObj）
（vla put DisplayLocked vpObj[：vlax true/：vlax false]）
其中：vlax true锁定它，而：vlax false解锁它。

然后，要在lisp例程中在图纸空间和模型空间之间切换，可以按以下方式使用TILEMODE：
以下内容归功于Zorg：

copy


(defun c:mm( / )
(command "_tilemode" "1")
)
(defun c:pm( / )
(command "_tilemode" "0")
)

不确定“提取”实体是什么意思。。。。

然后不是终止命令，而是允许用户选择视口。。。。你可以使用这个函数，由Lee Mac编写

copy


(defun c:vpon ( / d s )
   (vl-load-com)
   (if (setq s (ssget "_+.:S:E:L" '((0 . "VIEWPORT"))))
       (progn
           (setq d (vla-get-activedocument (vlax-get-acad-object)))
           (vla-put-mspace d :vlax-true)
           (vla-put-activeviewport d (vlax-ename->vla-object (ssname s 0)))
       )
   )
   (princ)
)
(defun c:vpoff ( )
   (vla-put-mspace (vla-get-activedocument (vlax-get-acad-object)) :vlax-false)
   (princ)
)