需要lisp来更改colo

MikeP · 发表于 2022-7-5 23:38:47

有没有办法访问可以轻松更改命令行颜色的变量。我试着做的是创建一个计时器。这个计时器将帮助我跟踪给定工作的时间量。当计时器处于活动状态时，我希望命令行为绿色或白色。但当计时器关闭时，我希望命令行变为红色。这样，我就不会忘记打开或关闭计时器。

David Bethel · 发表于 2022-7-5 23:43:26

我会在MODEMACRO中寻找一种显示定时器开/关状态显示的方法。希望这些年来它没有发生太大的变化或中断-大卫

MikeP · 发表于 2022-7-5 23:46:02

我现在使用mode宏。它用来在屏幕底部显示我的名字，哈哈。但是你怎么让它改变命令行的颜色呢

Lee Mac · 发表于 2022-7-5 23:49:29

试一试：

用r、g、b颜色呼叫

copy


;; Command Line Colour Change by Lee Mac
(defun CmdCol (r g b)
 (vl-load-com)
 (vla-put-TextWinBackgrndColor
   (vla-get-Display
     (vla-get-Preferences
       (vlax-get-acad-object))) (+ r (* 256 g) (* 65536 b))))
;; Test Function
(defun c:test ()
 (cmdcol 0 255 0)
 (princ))

MikeP · 发表于 2022-7-5 23:52:01

你总是能帮我解决问题：D.现在我该如何设置它，以使每个新图形都在默认的休息时间打开（红色）

Lee Mac · 发表于 2022-7-5 23:57:28

你可以把这个扔进你的阿卡多克。lsp-我把它做成了一个开关

copy


;; Command Line Colour Change by Lee Mac
(defun CmdCol (r g b)
 (vl-load-com)
 (vla-put-TextWinBackgrndColor
   (vla-get-Display
     (vla-get-Preferences
       (vlax-get-acad-object))) (+ r (* 256 g) (* 65536 b))))
(CmdCol 255 127 127)
(defun c:Timer ()
 (vl-load-com)
 (cond ((not *TimeFlag*)
        (vl-cmdf "_.time" "_R" "_ON" "")
        (CmdCol 191 255 127)
        (setq *TimeFlag* T))
       (t (vl-cmdf "_.time" "_OFF" "")
        (CmdCol 255 127 127)
        (setq *TimeFlag* nil)))
 (princ))