批处理属性编辑器

bababarghi · 发表于 2022-7-6 06:18:18

大家好，

我的数百个图形中有一个块，现在我需要将其中一个属性的宽度因子值从1.0更改为0.9。我可以使用LSP程序吗？

我也尝试过脚本，但由于我糟糕的脚本技能，这是一次不成功的练习。

干杯

CheSyn · 发表于 2022-7-6 06:26:06

可以使用脚本调用LISP例程。块/属性的名称是什么？

bababarghi · 发表于 2022-7-6 06:27:25

我找到了一个LSP可以帮我：

(defun c:att_width(/ att_en width_x ed)
(setq att_en (car (nentsel "\nSelect attribute to change \n")))
(setq ed (entget att_en))
(if (= (cdr(assoc 0 ed)) "ATTRIB")
(progn
(setq width_x (getreal "\nEnter width factor \n"))
(setq ed (subst (cons 41 width_x ) (assoc 41 ed) ed ))
(entmod ed)
(entupd att_en)
(princ)
)
(princ "\nEntity is not an attribute ")
)
(princ)
)

遗憾的是，这个lisp的设计要求用户交互选择一个属性，这是一个通过脚本部署的繁琐过程（我更喜欢按名称选择一个块）

我的块名是“MRM”（标题块），有一个属性的标签名是“DATE-5”，我特别关注这个属性。如果我可以在“DATE-1”、“DATE-2”上应用相同的宽度因子变化，那就更好了，同时“DATE-5”。

谢谢

Dadgad · 发表于 2022-7-6 06:31:15

你可以试试李·麦克的优秀网站上的lisp。
http://www.lee-mac.com/macatt.html

如果这不是任务的最佳选择，那么还有很多其他选择，
浏览Lee的可用Lisp库。

谢谢李！

bababarghi · 发表于 2022-7-6 06:38:26

李无疑是LSP大师。但lisp与属性属性无关。只能设置值。

CheSyn · 发表于 2022-7-6 06:43:45

试试这个

copy


(defun c:test ( / blk att)
   (if
       (setq blk (ssget "_x" '((2 . "MRM"))))
       (progn
           (setq blk (ssname blk 0)
                 att (entnext blk))
           (while
               (/=
                   (cdr (assoc 0 (entget att)))
                   "SEQEND"
               )
                   (if
                       (=
                           (strcase "DATE-")
                           (substr (cdr (assoc 2 (entget att))) 1 5)
                       )
                       (progn
                           (entmod
                               (subst
                                   (cons 41 0.9)
                                   (assoc 41 (entget att))
                                   (entget att)
                               )
                           )
                               (entupd att)
                       )
                   )
               (setq att (entnext att))
           )
       )
       (princ "\nMRM not in drawing!")
   )
 (princ)
)