[编程交流] 过滤/分离字母/nu

[color=GREEN];; Split String  -  Lee Mac[/color]
[color=GREEN];; Splits a string into a list of text and numbers[/color]
([color=BLUE]defun[/color] LM:splitstring ( str )
   (
       ([color=BLUE]lambda[/color] ( l )
           ([color=BLUE]read[/color]
               ([color=BLUE]strcat[/color] [color=MAROON]"("[/color]
                   ([color=BLUE]vl-list->string[/color]
                       ([color=BLUE]apply[/color] '[color=BLUE]append[/color]
                           ([color=BLUE]mapcar[/color]
                               ([color=BLUE]function[/color]
                                   ([color=BLUE]lambda[/color] ( a b c )
                                       ([color=BLUE]cond[/color]
                                           (   ([color=BLUE]=[/color] 92 b)
                                               ([color=BLUE]list[/color] 32 34 92 b 34 32)
                                           )
                                           (   ([color=BLUE]or[/color] ([color=BLUE]<[/color] 47 b 58)
                                                   ([color=BLUE]and[/color] ([color=BLUE]=[/color] 45 b) ([color=BLUE]<[/color] 47 c 58) ([color=BLUE]not[/color] ([color=BLUE]<[/color] 47 a 58)))
                                                   ([color=BLUE]and[/color] ([color=BLUE]=[/color] 46 b) ([color=BLUE]<[/color] 47 a 58) ([color=BLUE]<[/color] 47 c 58))
                                               )
                                               ([color=BLUE]list[/color] b)
                                           )
                                           (   ([color=BLUE]list[/color] 32 34 b 34 32))
                                       )
                                   )
                               )
                               ([color=BLUE]cons[/color] [color=BLUE]nil[/color] l) l ([color=BLUE]append[/color] ([color=BLUE]cdr[/color] l) '(( )))
                           )
                       )
                   )
                   [color=MAROON]")"[/color]
               )
           )
       )
       ([color=BLUE]vl-string->list[/color] str)
   )
)

_$ (LM:splitstring "ab12c-3.1de4.2f56")
("a" "b" 12 "c" -3.1 "d" "e" 4.2 "f" 56)

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(defun kg:SsgetFilterReal ()
 '(
   (1 . "~*[~-.0-9]*") ; only minus signs, decimal points and numbers allowed
   (1 . "*`.*")        ; there must be one decimal point
   (1 . "~*`.*`.*")    ; only one decimal point allowed
   (-4 . "<OR")
     (1 . "~*-*")      ; there is no minus sign
     (-4 . "<AND")
       (1 . "-*")      ; the minus sign must be the first character
       (1 . "~*-*-*")  ; only one minus sign allowed
     (-4 . "AND>")
   (-4 . "OR>")
 )
)
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(defun c:Comp (/ ent ss i lst)
 (if
   (and
     (setq ent (entsel "\nPlease select a text for style, layer and text height filtering: "))
     (setq ent (entget (car ent)))
     (or
       (equal '(0 . "TEXT") (assoc 0 ent))
       (prompt "\nNot a text ")
     )
     (or
       (setq ss
         (ssget
           "_X"
           (vl-list*
             '(0 . "TEXT")
             (assoc 7 ent)        ; style of digit text 
             (assoc 8 ent)        ; selected layer name
             (assoc 40 ent)       ; selected text height
             (assoc 410 ent)      ; current tab only
             ;; numerical text filtering:
                  (kg:SsgetFilterReal)
           )
         )
       )
       (prompt "\nNo selection ")
     )
   )
   (mapcar
     '(lambda (a) (cdr (assoc 1 (entget a))))
     (repeat (setq i (sslength ss))
       (setq lst (cons (ssname ss (setq i (1- i))) lst))
     )
   )
 )
)
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;