[编程交流] 外部参照Lisp例程

(defun c:xrx ( / xn xr )
   (while
       (progn (setvar 'ERRNO 0) (setq xr (car (entsel "\nSelect XRef to Detach: ")))
           (cond
               (   (= 7 (getvar 'ERRNO))
                   (princ "\nMissed, try again.")
               )
               (   (eq 'ENAME (type xr))
                   (if
                       (not
                           (and
                               (eq "INSERT" (cdr (assoc 0 (entget xr))))
                               (= 4 (logand 4 (cdr (assoc 70 (tblsearch "BLOCK" (setq xn (cdr (assoc 2 (entget xr)))))))))
                           )
                       )
                       (princ "\nObject is not an XRef.")
                   )
               )
           )
       )
   )
   (if xr (vla-detach (vlax-ename->vla-object (cdr (assoc 330 (entget (tblobjname "BLOCK" xn)))))))
   (princ)
)
(vl-load-com) (princ)

(defun c:xrr nil
   (vlax-for block (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object)))
       (if (eq :vlax-true (vla-get-isxref block)) (vla-reload block))
   )
   (princ)
)
(vl-load-com) (princ)

;; turn off all xref layers
(defun c:XF (/) (command "_.-layer" "_off" "*|*" "") (princ))
;; turn on all xref layers
(defun c:XN (/) (command "_.-layer" "_on" "*|*" "") (princ))
;UNLOAD ALL XREFS
(defun c:xu (/) (command "_.-xref" "_UNLOAD" "*") (princ))
;RELOAD ALL XREFS
(defun c:XE (/) (command "_.-xref" "_RELOAD" "*" ) (princ))

(defun c:xo nil (command "_.xopen" pause) (princ))