[编程交流] 闭合多段线的图案填充

(defun C:PL2CAN ()
(setvar "PEDITACCEPT" 1)
(setvar "CMDECHO" 1)
(setq gru(ssget '((0 . "LWPOLYLINE")))
      index -1
      modelspace(vla-get-Modelspace (vla-get-activedocument(vlax-get-acad-object)))
)
(setvar "HPNAME" "ANSI31")
(setvar "HPSCALE" 1)
(repeat (sslength gru)
 (setq spessore(vla-get-ConstantWidth (vlax-ename->vla-object (ssname gru (setq index(1+ index))))))
 (vla-put-ConstantWidth (vlax-ename->vla-object (ssname gru index)) 0.0)
 (setq ent1(car(vlax-safearray->list (vlax-variant-value (vla-offset (vlax-ename->vla-object (ssname gru index)) (/ spessore 2))))))
 (setq ent2(car(vlax-safearray->list (vlax-variant-value (vla-offset (vlax-ename->vla-object (ssname gru index)) (-(/ spessore 2)))))))
 (setq coord1 (variant2lista (vla-get-coordinates ent1) 2))
 (setq coord2 (variant2lista (vla-get-coordinates ent2) 2))
 (cond
  ((eq (vla-get-Closed ent1) :vlax-true)
   (vl-cmdf "_HATCH" "" "" "" (vlax-vla-object->ename ent1)(vlax-vla-object->ename ent2) "")
  )
  ((eq (vla-get-Closed ent1) :vlax-false) 
   (vla-addLine modelspace (vlax-3d-point (car coord1))(vlax-3d-point (car coord2)))
   (vl-cmdf "_PEDIT" (entlast) "_J" (vlax-vla-object->ename ent1)(vlax-vla-object->ename ent2) "" "_CL" "")
   (vl-cmdf "_HATCH" "" "" "" (entlast) "")
  )
 ) 
)
)
;;; ***************************FUNZIONE VARIANT2LISTA*******************************
;;; Trasforma un variant in una lista a gruppi con numero elementi per gruppo
(defun variant2lista (listavariant numero / listaparz listafin)
(setq listaparz '()
      listafin   '()
)
(foreach elemento (vlax-safearray->list (vlax-variant-value listavariant))
 (setq listaparz (append listaparz (list elemento)))
 (if (= (length listaparz) numero)
  (setq listafin  (append listafin (list listaparz))
    listaparz '()
  )
 )
)
listafin
)

(defun c:hatsoff ( / ss e ent fp sp el el2 elj)
(setvar 'cmdecho 0)      
             
(if     (and  (setq dist (getdist "\nEnter Offset Distance: "))  
                     (setq ss (ssget '((0 . "LWPOLYLINE")))))
(repeat (sslength ss)
   (if (and
(setq e (ssname ss 0))
(setq ent (entget e))
(setq  fp (assoc 10 ent) ent (member fp ent)
              sp (cdr (assoc 10 (cdr ent))) fp (cdr fp))
(setq fp (polar fp (setq ang (+ (angle fp sp) (/ pi 2.0)))  dist))
(not (command "_offset"  dist e "_non" fp "E"))
(setq el (entlast))
(not (eq el e))
(not (command "_offset"  dist e "_non" (setq sp (polar fp (+ ang pi) (+ dist dist))) "E"))
(setq el2 (entlast))
(not (eq el el2)))
        (progn
               (if (= 1 (cdr (assoc 70 (entget el))))
                (command "_hatch" "ANSI31" "" "" "_s" el el2 "")
                (progn  
                (command "_pline" "_non" fp "_non" sp "")
                (command "_pedit" "_multiple" el el2 (entlast) "" "_join" "" "")
                (setq elj (entget (entlast)))
                (entmod (subst '(70 . 1) (assoc 70  elj) elj))
                       (setvar 'Hpname "ANSI31")
                (command "_hatch" "" "" ""  (entlast) "")
                )
                  )
        )
       )
(ssdel e ss)
     )
)
             (princ)
            )