框中的文本

assafius · 发表于 2022-7-6 07:28:54

你好

我在模型空间中有一个文本实体。

假设我可以完美地检索其边界框的坐标。

现在，我有一个具有特定大小的矩形，我希望将文本插入到矩形中，并保持良好的匹配。如何用lisp将文本高度调整为矩形的尺寸？

谢谢！

Lee Mac · 发表于 2022-7-6 07:36:34

可能使用“适合”文本对齐方式，将文本高度设置为矩形的高度。

作为一个非常简单的示例，请考虑：

(defun c:tfit ( / a b e p q )
   (if
       (and
           (progn
               (while
                   (progn (setvar 'errno 0) (setq e (car (entsel "\nSelect Text: ")))
                       (cond
                           (   (= 7 (getvar 'errno))
                               (princ "\nMissed, try again.")
                           )
                           (   (= 'ename (type e))
                               (if (/= "TEXT" (cdr (assoc 0 (entget e))))
                                   (princ "\nObject is not Text.")
                               )
                           )
                       )
                   )
               )
               (= 'ename (type e))
           )
           (setq e (entget e))
           (setq a (getpoint "\nSpecify first corner: "))
           (setq b (getcorner a "\nSpecify opposite corner: "))
           (setq p (mapcar 'min a b)
                 q (mapcar 'max a b)
           )
       )
       (entmod
           (subst '(72 . 5) (assoc 72 e)
               (subst '(73 . 0) (assoc 73 e)
                   (subst (cons 10 p) (assoc 10 e)
                       (subst (list 11 (car q) (cadr p) 0.0) (assoc 11 e)
                           (subst (cons 40 (- (cadr q) (cadr p))) (assoc 40 e) e)
                       )
                   )
               )
           )
       )
   )
   (princ)
)