[编程交流] AutoLisp例程帮助

(defun c:arcoff ( / en ex )
   (while
       (progn (setvar 'errno 0) (setq en (car (entsel "\nSelect Arc: ")))
           (cond
               (   (= 7 (getvar 'errno))
                   (princ "\nMissed, try again.")
               )
               (   (= 'ename (type en))
                   (if (= "ARC" (cdr (assoc 0 (setq ex (entget en)))))
                       (command "_.offset"
                           (*  (cdr (assoc 40 ex))
                               (rem (+ pi pi (- (cdr (assoc 51 ex)) (cdr (assoc 50 ex)))) (+ pi pi))
                           )
                           en "\" ""
                       )
                       (princ "\nObject is not an Arc.")
                   )
                   t
               )
           )
       )
   )
   (princ)
)

(vl-load-com)
(defun c:OFAM () (c:OffsetArcMultiple))
(defun c:OffsetArcMultiple (/ *error* eName acDoc oArc)
 (princ "\rOFFSETARCMULTIPLE ")
 (defun *error* (msg)
   (if acDoc
     (vla-endundomark acDoc)
   )
   (cond ((not msg))                                                   ; Normal exit
         ((member msg '("Function cancelled" "quit / exit abort")))    ; <esc> or (quit)
         ((princ (strcat "\n** Error: " msg " ** ")))                  ; Fatal error, display it
   )
   (princ)
 )
 (while (and (/= nil (setq eName (car (entsel "\nSelect arc to offset: "))))
             (= "ARC" (cdr (assoc 0 (entget eName))))
        )
   (progn
     (or
       acDoc
       (not
         (vla-startundomark
           (setq acDoc (vla-get-activedocument (vlax-get-acad-object)))
         )
       )
     )
     (vla-offset
       (setq oArc (vlax-ename->vla-object eName))
       (vla-get-arclength oArc)
     )
     (*error* nil)
   )
 )
)

(defun c:arcoff ( / _select en ex )
   (defun _select ( msg obj / en )
       (while
           (progn (setvar 'errno 0) (setq en (car (entsel msg)))
               (cond
                   (   (= 7 (getvar 'errno))
                       (princ "\nMissed, try again.")
                   )
                   (   (= 'ename (type en))
                       (if (not (wcmatch (cdr (assoc 0 (entget en))) obj))
                           (princ "\nInvalid object selected.")
                       )
                   )
               )
           )
       )
       en
   )
   (if (setq en (_select "\nSelect Object to Offset: " "*LINE"))
       (while (setq ex (_select "\nSelect Arc: " "ARC"))
           (setq ex (entget ex))
           (command "_.offset"
               (*  (cdr (assoc 40 ex))
                   (rem (+ pi pi (- (cdr (assoc 51 ex)) (cdr (assoc 50 ex)))) (+ pi pi))
               )
               en "\" ""
           )
           (setq en (entlast))
       )
   )
   (princ)
)