在LISP文件中获取错误

gS7 · 发表于 2022-7-6 07:53:35


(defun c:test()
  (setq ss(ssget "x" (list (cons 0 "TEXT") (cons 1 "0.0,0.00,0.000,0.0000"))))
  [color="red"](if(= ss nil)
    (princ "\nNo Valid Objects Found !!") (exit)
  )[/color]
 
 (progn
   (initget "Y N")
   (setq user(getkword (strcat "\nFound :<"(rtos (sslength ss) 2 0)">: 0.0 Objects Do u want Erase Them? <Yes>/No:")))
   (if(= user nil)
     (setq user "Y")
   )
   (progn
     (if(= user "Y")
(progn
  (command "ERASE" SS "")
         (princ(strcat "\n < "(rtos (sslength ss) 2 0)" > Objects Erase From Drawing"))
)
(princ"\nNothing Erased From Drawing:")
     )
   )
 )(princ)
)

你好伙计们。。。。

请修复此Lisp函数。。。。我出错了。。。当在图形中找不到对象时。。（标记为红色）我想向用户报告错误。。。。。当我运行此文件时，它显示

copy

No Valid Objects Found !!
Error:bad argument type: lselsetp nil

这样地

对不起，我的周英语

pBe · 发表于 2022-7-6 08:06:34

copy

(defun c:test()
  
  (if (setq ss(ssget "x" (list (cons 0 "TEXT") (cons 1 "0.0,0.00,0.000,0.0000"))))
 (progn
   (initget "Y N")
   (setq user(getkword (strcat "\nFound :<"(rtos (sslength ss) 2 0)">: 0.0 Objects Do u want Erase Them? <Yes>/No:")))
   (if(= user nil)
     (setq user "Y")
   )
   (progn
     (if(= user "Y")
(progn
  (command "ERASE" SS "")
         (princ(strcat "\n < "(rtos (sslength ss) 2 0)" > Objects Erase From Drawing"))
)
(princ"\nNothing Erased From Drawing:")
     )
   )
 )(princ "\nNo Valid Objects Found !!") 
      )(princ)
)

Tharwat · 发表于 2022-7-6 08:13:23

现在试试。。。。

copy


(defun c:test (/ ss user)
 (if (and (setq ss
                 (ssget "_x"
                        (list (cons 0 "TEXT") (cons 1 "0.0,0.00,0.000,0.0000"))
                 )
          )
          (progn
            (initget "Y N")
            (setq user
                   (getkword
                     (strcat "\n Found :<"
                             (rtos (sslength ss) 2 0)
                             ">: 0.0 Objects Do u want Erase Them? <Yes>/No:"
                     )
                   )
            )
          )
     )
   (progn
     (if (= user "Y")
       (progn
         (command "_.ERASE" ss "")
         (princ (strcat "\n < "
                        (rtos (sslength ss) 2 0)
                        " > Objects Erase From Drawing"
                )
         )
       )
       (princ "\nNothing Erased From Drawing:")
     )
   )
   (princ "\nNo Valid Objects Found !!")
 )
 (princ)
)