[编程交流] 更改颜色、命令、更改

(defun C:revc ()
(command "color" "240")
(command "revcloud")
(command "color" "bylayer")
) ;end_defun

(setvar "CECOLOR" "240")
;your code here
(setvar "CECOLOR" "ByLayer")

 
(defun c:revc nil
(setvar 'Cecolor "240")
      (command "_.Revcloud")
       (while (> (getvar 'Cmdactive) 0)
                     (command pause))
       (setvar 'Cecolor "256")(princ)
     )

(defun c:TesT nil
 (command "_.revcloud")
 (while
   (= (getvar 'cmdactive) 1)
    (command pause)
 )
 (command "_.chprop" (entlast) "" "_color" 240 "")
 (princ)
)

Command: revc
_.Revcloud
Minimum arc length: 0.5000   Maximum arc length: 0.5000   Style: Normal
Specify start point or [Arc length/Object/Style] <Object>: [color=red]*Cancel*[/color]
Command: [color=red]; error: Function cancelled[/color]

(defun c:revc  ( / *error*)
 (defun *error*  (msg)
   (and oldCecolor (setvar 'cecolor oldCecolor))
   (cond ((not msg))                                                   ; Normal exit
         ((member msg '("Function cancelled" "quit / exit abort")))    ; <esc> or (quit)
         ((princ (strcat "\n** Error: " msg " ** "))))                 ; Fatal error, display it
   (princ))
 ((lambda (oldCecolor)
    (setvar 'cecolor "240")
    (command "._revcloud")
    (while (= (logand 1 (getvar 'cmdactive)) 1) (command pause))
    (*error* nil))
   (getvar 'cecolor)))

(vl-load-com)
(if (null *revcloudreactor*)
   (setq *revcloudreactor*
       (vlr-command-reactor nil
          '(
               (:vlr-commandwillstart . revcloudstore)
               (:vlr-commandended     . revcloudrestore)
               (:vlr-commandfailed    . revcloudrestore)
               (:vlr-commandcancelled . revcloudrestore)
           )
       )
   )
)
(defun revcloudstore ( reactor params )
   (if (wcmatch (strcase (car params)) "*REVCLOUD")
       (progn
           (setq *cecolor* (getvar 'CECOLOR))
           (setvar 'CECOLOR "240")
       )
   )
   (princ)
)
(defun revcloudrestore ( reactor params )
   (if (and *cecolor* (wcmatch (strcase (car params)) "*REVCLOUD"))
       (progn
           (setvar 'CECOLOR *cecolor*)
           (setq *cecolor* nil)
       )
   )
   (princ)
)
(princ)