添加默认值和makin

Michaels · 发表于 2022-7-6 08:16:20

你好

这里有一个链接，李这是真的非常好，并想添加一些东西，如果可能的话。

链接>>脱下

1-将我输入的第一个值作为默认值，并接受[是，否]
2-根据当前层制作偏移对象。

希望这是可能的。

谢谢

MSasu · 发表于 2022-7-6 08:30:39

有关提示器的默认值，请查看前面的讨论。

要将绘制操作的结果移动到当前层，可以尝试：

(command "_CHPROP" (entlast) "" "_LA" (getvar "CLAYER") "")

或：

copy

(setq OldLayer (getvar "CLAYER"))   ;store current layer
(setvar "CLAYER" MyDrawLayer)       ;switch to desired layer
; do draw actions here...
(setvar "CLAYER" OldLayer)          ;restore previous layer

当做
米尔恰

Lee Mac · 发表于 2022-7-6 08:46:05

更新版本：

http://lee-mac.com/doubleoffset.html

Michaels · 发表于 2022-7-6 08:47:56

谢谢你的想法，

谢谢李，效果很好。（尽管我希望它使用多个选择集）

非常感谢你。

Lee Mac · 发表于 2022-7-6 09:02:46

双偏移：

copy

(defun c:dOff ( / doc sel )
   (if
       (and
           (ssget "_:L" '((0 . "ARC,CIRCLE,ELLIPSE,*LINE")))
           (setq *of (cond ((getdist (strcat "\nSpecify Offset" (if *of (strcat " <" (rtos *of) ">: ") ": ")))) (*of)))
       )
       (progn
           (vla-startundomark (setq doc (vla-get-activedocument (vlax-get-acad-object))))
           (vlax-for obj (setq sel (vla-get-activeselectionset doc))
               (foreach off (list *of (- *of)) (vl-catch-all-apply 'vla-offset (list obj off)))
           )
           (vla-delete sel)
           (vla-endundomark doc)
       )
   )
   (princ)
)
(vl-load-com) (princ)

双偏移到当前层：

copy

(defun c:dOffc ( / doc lay sel )
   (if
       (and
           (ssget "_:L" '((0 . "ARC,CIRCLE,ELLIPSE,*LINE")))
           (setq *of (cond ((getdist (strcat "\nSpecify Offset" (if *of (strcat " <" (rtos *of) ">: ") ": ")))) (*of)))
       )
       (progn
           (setq lay (getvar 'CLAYER))
           (vla-startundomark (setq doc (vla-get-activedocument (vlax-get-acad-object))))
           (vlax-for obj (setq sel (vla-get-activeselectionset doc))
               (foreach off (list *of (- *of))
                   (if (not (vl-catch-all-error-p (setq err (vl-catch-all-apply 'vlax-invoke (list obj 'offset off)))))
                       (foreach obj err (vla-put-layer obj lay))
                   )
               )
           )
           (vla-delete sel)
           (vla-endundomark doc)
       )
   )
   (princ)
)
(vl-load-com) (princ)

Michaels · 发表于 2022-7-6 09:15:59

李太棒了。

非常感谢你。

迈克尔

Lee Mac · 发表于 2022-7-6 09:17:20

不客气

[编程交流] 添加默认值和makin

发表回复

精选推荐