使十字线在dur中可见

Qonfire · 发表于 2022-7-6 08:19:34

你好

我需要一个技巧，如何使十字头发在getcorner函数期间可见。十字线在第二个拾取点期间消失。

(setq zonearea (getcorner (setq origin (getpoint))  "corner" ))

谢谢

Lee Mac · 发表于 2022-7-6 08:46:15

据我所知，实现这一点的唯一方法是创建一个函数来模拟getcorner函数的行为，使用grread函数来监视光标位置。

例如：

copy

;; Get Corner  -  Lee Mac
;; A grread substitution for the getcorner function
;; pt  -  A point to be used as the base point.
;; msg -  A string to be displayed to prompt the user.
;; Returns: Selected UCS point, else nil
(defun LM:GetCorner ( pt msg / gr pl )
   (if msg (princ msg))
   (while (= 5 (car (setq gr (grread t 13 0))))
       (redraw)
       (setq gr (cadr gr)
             pl (list pt (list (car gr) (cadr pt))
                      gr (list (car pt) (cadr gr))
                )
       )
       (mapcar 'grdraw pl (cons (last pl) pl) '(-1 -1 -1 -1))
   )
   (redraw)
   (if (listp (cadr gr)) (cadr gr))
)

copy


(if (setq p1 (getpoint "\nFirst Point: "))
   (LM:GetCorner p1 "\nNext Point: ")
)

Qonfire · 发表于 2022-7-6 09:00:50

谢谢你的回复，它变得有点太多了，我不需要看到那么严重的十字线。它奇怪的第一个交叉点在那里，但在第二个点它消失了。

Lee Mac · 发表于 2022-7-6 09:38:00

这是AutoCAD的标准行为-对于窗口/交叉选择也会发生同样的情况。

[编程交流] 使十字线在dur中可见

发表回复

精选推荐