与多段线点的距离

jhonnying · 发表于 2022-7-6 08:39:45

大家好！你能帮我用一个lsp程序自动生成从多段线的点到参考线的线性尺寸吗，因为用经典的comand（dimlinear）我可以一次画出每个点的尺寸线。我附上了一张图纸，以便您更好地理解。请原谅我的英语！

谢谢
多段线点到参照线的距离。图纸

pBe · 发表于 2022-7-6 08:45:15

试试这个：

copy

(defun c:DimTwo(/ aDoc Space pl ReFL pt pt2 ss)
 (vl-load-com)
 (setq aDoc (vla-get-ActiveDocument (vlax-get-acad-object)))
 (setq Space
 (if (= 1 (getvar "CVPORT"))
   (vla-get-PaperSpace aDoc)
   (vla-get-ModelSpace aDoc)
 )
 )
 (prompt "\nSelect Polyline:")
 (if (and
(setq Pl (ssget ":E:S:L" '((0 . "LWPOLYLINE"))))
(progn (prompt "\nSelect Reference Line:")
       (setq RefL (ssget ":E:S:L" '((0 . "*LINE"))))
)
     )
   (progn
     (setq RefL (vlax-ename->vla-object (ssname RefL 0)))
     (foreach pt (mapcar
     'cdr
     (vl-remove-if-not
       '(lambda (x) (= (car x) 10))
       (entget (ssname pl 0))
     )
   )
(vla-addDimRotated
  space
  (vlax-3d-point (append pt '(0.0)))
  (vlax-3d-point
    (setq pt2 (vlax-curve-getclosestpointto RefL pt))
  )
  (vlax-3d-point
    (mapcar (function (lambda (a b) (/ (+ a b) 2.))) pt pt2)
  )
  1.57079633
)
     )
   )
 )(princ)
)