[编程交流] 需要有关检查select的帮助

;this routine will let the user select multiple object
;& PASTEBLOCK the selection - 112011
;-
(defun c:pblk (/ bp opt selx)
;-
(princ "Select basepoint: ") 
(setq bp (getpoint))
(setq opt "_b")
;-
(setq selx (ssget))
;-
[color="blue"];check the selection set "selx" if there is any "WIPEOUT" entity selected
;if "wipeout" is/ are PRESENT (command:"_.draworder" "wipeout" opt)
;(alert "wipeout found -> sent to back")
;proceed to next
;if wipeout is/ are NOT found
;(alert "wipeout NOT found")
;proceed to next[/color]
;-
(command "_.copybase" bp selx "") 
(command "_.pasteblock" bp)
(command "_.erase" "previous" "")
(princ)
);end defun
;;;

(defun c:TesT (/ ss i sn)
 ;; Tharwat 16. Nov. 2011 ;;
 (if (setq ss (ssget '((0 . "WIPEOUT"))))
   (progn
     (repeat (setq i (sslength ss))
       (setq sn (ssname ss (setq i (1- i))))
       (command "_.draworder" sn "" "_b")
     )
     (alert (strcat "wipeout found -> sent to back"
                    "\t"
                    "("
                    (itoa (sslength ss))
                    ")"
            )
     )
   )
   (alert "wipeout NOT found")
 )
 (princ)
)

(defun c:Test (/ ss pt ss2)
 (if (and (setq ss (ssget "_:L")) (setq pt (getpoint "\nSpecify basepoint: ")))
   (progn (if (setq ss2 (ssget "_P" '((0 . "WIPEOUT"))))
            (command "_.draworder" ss2 "" "_back")
          )
          (command "_.copybase" "_non" pt ss "" "_.pasteblock" "_non" pt "_.erase" ss "")
   )
 )
 (princ)
)