询问纸张大小

johmmeke · 发表于 2022-7-6 09:17:17

我得到的图纸有10到50个布局的al大小的混乱没有页面设置，现在我必须去布局布局，以设置正确的页面设置。。。
所以我喜欢的是一个例行程序，它“扫描”布局，并给出一个列表，其中列出了每个布局的大小。所以我可以使用pagesetup例程在组中设置相应的页面。

对不起，不是母语英语，所以解释可能有点奇怪；

Tharwat · 发表于 2022-7-6 09:19:04

这就是你的意思吗？

copy


(defun c:TesT (/ papersize prnt)
 (vl-load-com)
;;; Tharwat 19. Oct. 2011 ;;;
 (foreach x (layoutlist)
   (cond ((not lay)
          (setq lay (vla-get-activelayout
                      (vla-get-activedocument (vlax-get-acad-object))
                    )
          )
         )
   )
   (setq papersize (vla-getpapersize lay 'w 'h))
   (setq prnt (cons (strcat "Name of layout :"
                            "  "
                            x
                            "  "
                            "Paper Size :"
                            " "
                            (rtos w 2 1)
                            "  "
                            (rtos h 2 1)
                    )
                    prnt
              )
   )
 )
 (foreach lays (reverse prnt)
   (print lays)
 )
 (textpage)
 (princ)
)

塔瓦特

johmmeke · 发表于 2022-7-6 09:21:38

这就是我的意思

但我每次测试A4和A4肖像A1和A0时，都会从你的例程210 297中得到相同的尺寸

但我的外表

thx Tharwat公司

Tharwat · 发表于 2022-7-6 09:26:37

你说得对，纸的大小总是一样的。我不知道为什么！！

designerstuart · 发表于 2022-7-6 09:28:19

谢谢你的邀请，但我不能让它工作。我没有收到任何错误消息，也没有从autocad执行任何操作。
我加载lisp（拖放），然后运行它（命令测试）
插入点0,0,0正确，我的块名与lisp中的名称相同
我忘了什么吗？

我应该更改这一行吗？（cons 2 Block）；；Block的名称？

谢谢你的时间

Lee Mac · 发表于 2022-7-6 09:31:22

由于您始终在活动布局对象上操作，因此不会更改：

试试这个：

copy

(defun c:test ( / width height )
   (vlax-for layout (vla-get-layouts (vla-get-activedocument (vlax-get-acad-object)))
        (if (not (eq "MODEL" (strcase (vla-get-name layout))))
            (progn
                (vla-getpapersize layout 'width 'height)
                (princ
                    (strcat "\n" (vla-get-name layout)
                        ", Paper Size: " (rtos width 2 2) " x " (rtos height 2 2)
                    )
                )
            )
        )
   )
   (princ)
)
(vl-load-com) (princ)