复制多行属性数据

pmxcad · 发表于 2022-7-6 08:52:40

你好
我正在寻找一个lisp，它从块中复制TAG1中的多行属性数据，并将其粘贴到命令行/promt。

谢谢

庄信万丰

Lee Mac · 发表于 2022-7-6 08:57:55

以下是一个函数，用于从多行文字属性、属性、多行文字或文字实体返回textstring：

(defun _gettextstring ( ename )
   (apply 'strcat
       (apply 'append
           (mapcar
               (function
                   (lambda ( pair )
                       (if (member (car pair) '(1 3))
                           (list (cdr pair))
                       )
                   )
               )
               (entget ename)
           )
       )
   )
)

使用“command”功能将文本提交到命令行。

Tharwat · 发表于 2022-7-6 08:59:20

大概

copy


(defun c:test (/ acdoc ss sset nme)
 (vl-load-com)
 (setq acdoc (vla-get-activedocument (vlax-get-acad-object)))
 (if (setq ss (ssget "+.:S" '((0 . "INSERT")(66 . 1))))
   (progn
     (setq sset (ssname ss 0))
     (setq nme (cdr (assoc 2 (entget sset))))
     (vlax-for x (vla-item (vla-get-blocks acdoc) nme)
       (if (eq (vla-get-objectname x) "AcDbAttributeDefinition")
         (princ (vla-get-tagstring x))
       )
     )
   )
   (princ)
 )
 (princ)
)

Tharwat

Tharwat · 发表于 2022-7-6 09:05:09

多个标签还有一个。。。。。

copy


(defun c:test (/ acdoc ss strngs)
 (vl-load-com)
 (setq acdoc (vla-get-activedocument (vlax-get-acad-object)))
 (if (setq ss (ssget "+.:S" '((0 . "INSERT") (66 . 1))))
   (vlax-for x (vla-item (vla-get-blocks acdoc)
                         (cdr (assoc 2 (entget (ssname ss 0))))
               )
     (if (eq (vla-get-objectname x) "AcDbAttributeDefinition")
       (setq strngs (cons (vla-get-tagstring x) strngs))
     )
   )
   (princ)
 )
 (print strngs)
 (princ)
)