双曲螺线

andregustavo · 发表于 2022-7-6 09:26:33

大家好。我一直在寻找一个用于绘制hiperbolic螺旋的通用lisp例程，但找不到它。然而，Fuccaro有一个对数螺旋的脚本。由于我没有编程能力，可以重写脚本以使用以下等式吗

r=a/alpha

?
提前感谢

这是Fuccaro的对数螺线脚本（r=a*exp（b*alpha））

copy

;|draw a logarithmic spiral 
Miklos Fuccaro     [email="mfuccaro@hotmail.com"]mfuccaro@hotmail.com[/email] 
---------------------August 2006-------|; 
(defun c:logsp( / a b a1 ori osmode cmdecho) 
;a,b=curve paramethers 
;a1 =angular increment 
;ori=origin; set to the origin of the UCS 
 (princ "logarithmic spiral   R=a*exp(b*alpha)") 
 (setq a (getreal "\na=") 
  b (getreal "\tb=")) 
 (setq a1 0.1 alpha (- a1) ori '(0 0 0)) 
 (if (and a b) 
   (progn 
     (setq osmode (getvar "osmode") 
      cmdecho (getvar "cmdecho")) 
     (setvar "osmode" 0) 
     (setvar "cmdecho" 0) 
     (command "pline") 
     (repeat 1000    ;nr of points 
  (command (polar ori (setq alpha (+ alpha a1)) (* a (exp (* b alpha))))) 
  ) 
     (command "") 
     (setvar "osmode" osmode) 
     (setvar "cmdecho" cmdecho) 
     ) 
   (princ "Invalid input!") 
   ) 
 (princ) 
 )

fuccaro · 发表于 2022-7-6 09:36:51

您好，安德烈古斯塔沃，欢迎来到论坛！

这是您编写的执行的Lisp（r=a/alpha）：

copy

(defun c:hipsp( / a a1 alpha osmode cmdecho)
 (setq a (getreal "\na= ")
   a1 0.1
   alpha 0
   osmode (getvar "osmode")
   cmdecho (getvar "cmdecho"))
 (mapcar 'setvar '("osmode" "cmdecho") '(0 0))
 (command "pline")
 (repeat 500
   (command (polar '(0 0 0) (setq alpha (+ alpha a1)) (/ a alpha))))
 (command "")
 (mapcar 'setvar '("osmode" "cmdecho") (list osmode cmdecho))
 (princ)
 )

leninne · 发表于 2022-7-6 09:41:50

你好，Fuccaro！

我看到了你关于对数螺旋的代码，我知道这是一个lisp代码，但因为我在这方面很新，我不太知道如何创建lisp文件来加载它（我见过其他lisp文件，它们看起来不同，这就是为什么我如此困惑）。

我需要代码来创建一个将放置在天线中的螺旋。

真的真的需要你的帮助！

Lee Mac · 发表于 2022-7-6 09:48:35

一些螺旋。。。

对数螺线

copy


(defun c:LogSpiral ( / a0 i v p a b l )
 (setq a0 0.0  ;; Start Angle
       i  0.1  ;; Increment
       v  500  ;; Vertices
 )
 (princ "\nLogarithmic Spiral: r=ae^(b0)")
 (if
   (and
     (setq a (getreal "\nParameter a="))
     (setq b (getreal "\nParameter b="))
     (setq p (getpoint "\nBase Point: "))
   )
   (entmakex
     (append
       (list
         (cons 0 "LWPOLYLINE")
         (cons 100 "AcDbEntity")
         (cons 100 "AcDbPolyline")
         (cons 90 v)
       )
       (repeat v
         (setq l (cons (cons 10 (polar p (setq a0 (+ a0 i)) (* a (exp (* b a0))))) l))
       )
     )
   )
 )
 (princ)
)

双曲螺线

copy


(defun c:HypSpiral ( / a0 i v a p l )
 (setq a0 0.0  ;; Start Angle
       i  0.1  ;; Increment
       v  500  ;; Vertices
 )
 (princ "\nHyperbolic Spiral: r=a/x")
 (if
   (and
     (setq a (getreal "\nParameter a="))
     (setq p (getpoint "\nBase Point: "))
   )
   (entmakex
     (append
       (list
         (cons 0 "LWPOLYLINE")
         (cons 100 "AcDbEntity")
         (cons 100 "AcDbPolyline")
         (cons 90 v)
       )
       (repeat v
         (setq l (cons (cons 10 (polar p (setq a0 (+ a0 i)) (/ a a0))) l))
       )
     )
   )
 )
 (princ)
)

Archimian螺旋

费马螺线

copy


(defun c:FermatSpiral ( / a0 i v p l )
 (setq a0 0.0  ;; Start Angle
       i  0.1  ;; Increment
       v  250  ;; Vertices
 )
 (princ "\nFermat Spiral: r=+-0^0.5")
 (if (setq p (getpoint "\nBase Point: "))
   (entmakex
     (append
       (list
         (cons 0 "LWPOLYLINE")
         (cons 100 "AcDbEntity")
         (cons 100 "AcDbPolyline")
         (cons 90 (* 2 v))
       )
       (repeat v
         (setq l
           (append
             (list (cons 10 (polar p (setq a0 (+ a0 i)) (- (sqrt a0)))))
             l
             (list (cons 10 (polar p (setq a0 (+ a0 i)) (sqrt a0))))
           )
         )
       )
     )
   )
 )
 (princ)
)

Lituus螺旋

copy


(defun c:LituusSpiral ( / a0 i v p l )
 (setq a0 0.0  ;; Start Angle
       i  0.1  ;; Increment
       v  500  ;; Vertices
 )
 (princ "\nLituus Spiral: r=0^-0.5")
 (if (setq p (getpoint "\nBase Point: "))
   (entmakex
     (append
       (list
         (cons 0 "LWPOLYLINE")
         (cons 100 "AcDbEntity")
         (cons 100 "AcDbPolyline")
         (cons 90 v)
       )
       (repeat v
         (setq l (cons (cons 10 (polar p (setq a0 (+ a0 i)) (/ 1. (sqrt a0)))) l))
       )
     )
   )
 )
 (princ)
)