[编程交流] 通过AutoLISP关闭文件夹

(defun MT-Explore (Directory / Shell result)
   (setq Shell (vla-getInterfaceObject (vlax-get-acad-object)
                                       "Shell.Application"
               )
   )
   (setq result
            (vl-catch-all-apply 'vlax-invoke (list Shell 'Explore Directory))
   )
   (vlax-release-object Shell)
   (not (vl-catch-all-error-p result))
)

(defun LM:Terminate ( process / wmi server query name )
 (vl-catch-all-apply
   (function
     (lambda ( / name )
       (setq process (strcase process)
             wmi     (vlax-create-object "WbemScripting.SWbemLocator")
             server  (vlax-invoke wmi 'connectserver nil nil nil nil nil nil nil nil)
             query   (vlax-invoke server 'execquery "Select * from Win32_Process")
       )
       (vlax-for item query
         (if
           (and
             (setq name (vlax-get item 'commandline))
             (vl-string-search process (strcase name))
           )
           (vlax-invoke item 'terminate)
         )
       )
     )
   )
 )
 (foreach object (list wmi server query)
   (if (and object (not (vlax-object-released-p object)))
     (vlax-release-object object)
   )
 )
)

(LM:Terminate "Excel.exe")