[编程交流] 使用d选择实体

;;------------------=={ Sortents Table }==--------------------;;
;;                                                            ;;
;;  Retrieves the Sortents Table object.                      ;;
;;------------------------------------------------------------;;
;;  Author: Lee Mac, Copyright © 2010 - www.lee-mac.com       ;;
;;------------------------------------------------------------;;
;;  Arguments:                                                ;;
;;  space - VLA Layout Block Object                           ;;
;;------------------------------------------------------------;;
;;  Returns: Sortents Table Object, else nil                  ;;
;;------------------------------------------------------------;;
(defun LM:SortentsTable ( space / dict ) (vl-load-com)
 ;; © Lee Mac 2010
 (defun _catchapply ( foo args / result )
   (if
     (not
       (vl-catch-all-error-p
         (setq result
           (vl-catch-all-apply foo args)
         )
       )
     )
     result
   )
 )
 
 (cond
   (
     (_catchapply 'vla-item
       (list
         (setq dict
           (vla-GetExtensionDictionary space)
         )
        "ACAD_SORTENTS"
       )
     )
   )
   (
     (_catchapply 'vla-AddObject
       (list dict "ACAD_SORTENTS" "AcDbSortentsTable")
     )
   )
 )
)