坐标提取

Hari Prashanth · 发表于 2022-7-6 09:49:49

大家好。。。
Im使用autolisp将二维图形中的坐标提取到excel文件中。
我必须遵循一些关于数字的条件。。。
1、数字必须仅为正方体。
2、坐标提取必须始终从原点开始。ie（0,0）。
这是我遵循的程序。。。
我来画这个图。
2、使用“Divide”命令将其划分为多个节点。
3.加载以下lisp以提取电子表格中的坐标。

copy


;;;Select points and export their co-ords to *.csv file
;;;Written by ssg - October 23th, 2007
;;;=========================================
(defun C:EPEX(/ ss fn f e p)
(prompt "\nSelect points to export:")
(if not (setq ss (ssget '((0 . "POINT"))))
    (progn (alert "No objects selected!") (quit))
)
(if (not (setq fn (getfiled "Export to file" (getvar "dwgprefix") "csv" 1)))
   (progn (alert "No file selected!") (quit))
)
(setq f (open fn "w"))
(while (setq e (ssname ss 0))
   (setq p (cdr (assoc 10 (entget e))))
   (princ (strcat (rtos (car p)) "," (rtos (cadr p)) "," (rtos (caddr p)) "\n") f)
   (ssdel e ss)
)
(close f)
(alert (strcat "Finish export points to file: " fn))
)
;;;=========================================

我也附上了一个样本数字。。。
如有任何建议，我将不胜感激。
请帮忙。
被压抑。图纸

shoaib · 发表于 2022-7-6 09:59:29

先生，我无法理解答案是什么&如何设置

pBe · 发表于 2022-7-6 10:14:29

美好的

我能看到的唯一一件事是，如果你不小心选择了负值的“点”。。。它仍将写入csv文件。
设定一个忽略这些的条件，编写这样的代码会很有趣，不难，但很有趣

当你写条件的时候，如果你的一半分数在负象限，你只能得到你需要的一半。所以也要想一想。为了让它更具挑战性，可以随机选择每个点，但仍要按正确的顺序获取点。祝你好运

欢迎来到论坛，玩得开心

Lee Mac · 发表于 2022-7-6 10:21:19

正象限的滤波器可以直接合并到SelectionSet滤波器列表中，因此：

copy


(defun c:test ( / ss wf i p )
 ;; © Lee Mac 2011
 (cond
   (
     (and (setq ss (ssget '((0 . "POINT") (-4 . ">=,>=,*") (10 0.0 0.0 0.0))))
          (setq wf (getfiled "" "" "csv" 1))
          (setq wf (open wf "w"))
     )
     (repeat (setq i (sslength ss))
       (setq p (cdr (assoc 10 (entget (ssname ss (setq i (1- i)))))))
       (write-line (strcat (rtos (car p)) "," (rtos (cadr p)) "," (rtos (caddr p))) wf)
     )
     (close wf) (princ (strcat "\n--> " (itoa (sslength ss)) " Points Written to file."))
   )
 )
 (princ)
)