[编程交流] 在不同多边形中创建图案填充

(ssget '((0 . "LWPOLYLINE") (-4 . "<OR") (70 . 1) (70 . 129) (-4 . "OR>")))

((-1 . <Имя объекта: 7edf4508>) (0 . "LWPOLYLINE") (330 . <Имя объекта: 
7ed49cf8>) (5 . "6369") (100 . "AcDbEntity") (67 . 0) (410 . "Model") (8 . "0") 
(100 . "AcDbPolyline") (90 . 5) [b][color="Red"](70 . 0)[/color][/b] (43 . 0.0) (38 . 0.0) (39 . 0.0) 
[color="Blue"][b](10 -1632.64 5446.11)[/b][/color] (40 . 0.0) (41 . 0.0) (42 . 0.0) (91 . 0) (10 -330.423 
2953.1) (40 . 0.0) (41 . 0.0) (42 . 0.0) (91 . 0) (10 3128.59 4700.92) (40 . 
0.0) (41 . 0.0) (42 . 0.0) (91 . 0) (10 402.075 6001.62) (40 . 0.0) (41 . 0.0) 
(42 . 0.0) (91 . 0) [b][color="#0000ff"](10 -1632.64 5446.11)[/color][/b] (40 . 0.0) (41 . 0.0) (42 . 0.0) (91 
. 0) (210 0.0 0.0 1.0))

(defun c:Test (/ ss h)
 (vl-load-com)
 (if (setq ss (ssget '((0 . "LWPOLYLINE") (-4 . "<OR") (70 . 1) (70 . 129) (-4 . "OR>"))))
   ((lambda (space)
      (vlax-for x (setq ss (vla-get-activeselectionset *AcadDoc*))
        (vla-put-layer
          (setq h (vla-AddHatch space acHatchPatternTypePredefined "SOLID" :vlax-true))
          (vla-get-layer x)
        )
        (vlax-invoke h 'AppendOuterLoop (list x))
        (vlax-invoke h 'Evaluate)
      )
      (vla-delete ss)
    )
     (if (or (eq acmodelspace
                 (vla-get-activespace
                   (cond (*AcadDoc*)
                         ((setq *AcadDoc* (vla-get-activedocument (vlax-get-acad-object))))
                   )
                 )
             )
             (eq :vlax-true (vla-get-mspace *AcadDoc*))
         )
       (vla-get-modelspace *AcadDoc*)
       (vla-get-paperspace *AcadDoc*)
     )
   )
 )
 (princ)
)

(defun c:Test (/ ss h)
 (vl-load-com)
 (if (setq ss (ssget '((0 . "LWPOLYLINE"))))
   ((lambda (space)
      (vlax-for x (setq ss (vla-get-activeselectionset *AcadDoc*))
        (if (or (vlax-curve-isClosed x)
                (equal (vlax-curve-getStartPoint x) (vlax-curve-getEndPoint x))
            )
          (progn
            (vla-put-layer
              (setq h (vla-AddHatch space acHatchPatternTypePredefined "SOLID" :vlax-true))
              (vla-get-layer x)
            )
            (vlax-invoke h 'AppendOuterLoop (list x))
            (vlax-invoke h 'Evaluate)
          )
        )
      )
      (vla-delete ss)
    )
     (if (or (eq acmodelspace
                 (vla-get-activespace
                   (cond (*AcadDoc*)
                         ((setq *AcadDoc* (vla-get-activedocument (vlax-get-acad-object))))
                   )
                 )
             )
             (eq :vlax-true (vla-get-mspace *AcadDoc*))
         )
       (vla-get-modelspace *AcadDoc*)
       (vla-get-paperspace *AcadDoc*)
     )
   )
 )
 (princ)
)

(while
 (setq pt (getpoint "\n Internal Point :"))
   (command "_.-hatch" pt "_p" "SOLID" "" "")
 )