分解块

daisenson · 发表于 2022-7-6 10:20:01

大家好，

我试图用以下代码在一层中分解一些块

 
(defun c:440 ()
(ssget "x" '((0 . "insert")(8 . "440_xref")))
(command "explode" "p" "")
)

我得到以下错误：

命令：440
爆炸
选择对象：p
*无效的选择*
需要一个点或最后一个/全部/组
; 错误：功能已取消

我知道这是一个相当简单的动作，我甚至用纸片（使用ssx）尝试过，但当explode尝试获取之前的选择时，它无法识别。

知道怎么回事吗？

谢谢

Lee Mac · 发表于 2022-7-6 10:33:06

您可能需要使用以下内容：

copy


(defun c:440 ( / *error* ss qf )
 (defun *error* ( msg )
   (and qf (setvar 'QAFLAGS qf))
   (or (wcmatch (strcase msg) "*BREAK,*CANCEL*,*EXIT*")
       (princ (strcat "\n** Error: " msg " **")))
   (princ)
 )
 (if (setq ss (ssget "_X" '((0 . "INSERT") (8 . "440_xref"))))
   (progn
     (setq qf (getvar 'QAFLAGS))
     (setvar 'QAFLAGS 5)
     (command "_.explode" ss "")
     (setvar 'QAFLAGS qf)
   )
 )
 (princ)
)

Lee Mac · 发表于 2022-7-6 10:34:38

或者，使用VL：

copy


(defun c:440 ( / ss )
 (vl-load-com)
 (if (ssget "_X" '((0 . "INSERT") (8 . "440_xref")))
   (progn
     (vlax-for o
       (setq ss
         (vla-get-ActiveSelectionSet
           (vla-get-ActiveDocument
             (vlax-get-acad-object)
           )
         )
       )
       (if
         (not
           (vl-catch-all-error-p
             (vl-catch-all-apply 'vla-explode (list o))
           )
         )
         (vla-delete o)
       )
     )
     (vla-delete ss)
   )
 )
 (princ)
)

{未测试}

daisenson · 发表于 2022-7-6 10:42:24

我收集到QAFLAGS是我脚本中缺少的链接（仍在尝试找出它们是什么，尽管我收集到它们会阻止脚本同时选择多个对象）
有人说qaflags应该在1中，但在你的脚本和另一个线程中，我读了5。

有什么不同吗？

Lee Mac · 发表于 2022-7-6 10:51:54

两者都应该工作，第4位也会抑制警报框。

VVA · 发表于 2022-7-6 10:57:17

少量添加
从“关于命令分解的帮助”

copy


(defun c:440 ( / *error* ss qf i )
 (defun *error* ( msg )
   (and qf (setvar 'QAFLAGS qf))
   (or (wcmatch (strcase msg) "*BREAK,*CANCEL*,*EXIT*")
       (princ (strcat "\n** Error: " msg " **")))
   (princ)
 )
 (if (setq ss (ssget "_X" (list '(0 . "INSERT")'(8 . "440_xref")(cons 410 (getvar "CTAB")))))
   (progn
     (setq qf (getvar 'QAFLAGS))
     (setvar 'QAFLAGS 5)
     (setq i '-1)
     (repeat (sslength ss)
       (command "_.explode" (ssname ss (setq i (1+ i))) "")
       )
     (setvar 'QAFLAGS qf)
   )
 )
 (princ)
)