双面qleader。。ie箭头

Michael83 · 发表于 2022-7-6 10:23:16

我们使用双面引线显示地板/天花板托梁、椽子、桁架等的方向。。以典型方式。第二天，我将绘制一个200个不同长度的双面引线（闭合w/dimstyle引线设置为7）。除了绘制一个qleader，然后在第一个qleader的端点捕捉另一个qleader并回溯，还有更好的选择吗？。。创建一个块并拉伸末端并没有太大帮助。。在我的梦想世界中，有一种方法可以在开始和结束命令中绘制双面引线！谢谢你的帮助！

alanjt · 发表于 2022-7-6 10:33:54

快速。。。

copy

(defun c:TEst (/ p1 p2)
 (if (and (setq p1 (getpoint "\nSpecify first point: "))
          (setq p2 (getpoint p1 "\nSpecify next point: "))
     )
   (mapcar (function (lambda (a b) (command "_.leader" "_non" a "_non" b "" "" "_none")))
           (list p1 p2)
           (list p2 p1)
   )
 )
 (princ)
)

jake77777 · 发表于 2022-7-6 10:48:48

我研究了几个小时。我对你感激不尽！

alanjt · 发表于 2022-7-6 10:50:01

不客气。也可以使用拉伸参数创建动态块。

David Bethel · 发表于 2022-7-6 11:05:05

我不明白为什么这不起作用，但不同宽度的pline也应该起作用：

copy


(defun c:dld ();/ p1 p2)
 (initget 1)
 (setq p1 (getpoint "\nStart Point:   "))
 (initget 1)
 (setq p2 (getpoint p1 "\nEnd Point:   "))
 (setq p1 (list (car p1) (cadr p1))
       p2 (list (car p2) (cadr p2)))
 (entmake (list (cons 0 "LWPOLYLINE")
                (cons 100 "AcDbPolyline")
                (cons 90 4)
                (cons 70 0)
                (cons 38 (getvar "ELEVATION"))
                (cons 39 (getvar "THICKNESS"))
                (cons 70 0)
                (cons 10 p1)
                (cons 40 0)
                (cons 41 (/ (getvar "DIMASZ") 3.))
                (cons 42 0)
                (cons 10 (polar p1 (angle p1 p2) (getvar "DIMASZ")))
                (cons 40 0)
                (cons 41 0)
                (cons 42 0)
                (cons 10 (polar p2 (angle p2 p1) (getvar "DIMASZ")))
                (cons 40 (/ (getvar "DIMASZ") 3.))
                (cons 41 0)
                (cons 42 0)
                (cons 10 p2)
                (cons 40 0)
                (cons 41 0)
                (cons 42 0))))